mirror of
https://git.yoctoproject.org/poky
synced 2026-03-19 13:49:41 +01:00
18b1f0c340
Updating linux-yocto/6.12 to the latest korg -stable release that comprises
the following commits:
e03ced99c437 Linux 6.12.33
80fe1ebc1fbc Revert "drm/amd/display: more liberal vmin/vmax update for freesync"
d452b168da17 dt-bindings: phy: imx8mq-usb: fix fsl,phy-tx-vboost-level-microvolt property
1ed84b17fa9b dt-bindings: usb: cypress,hx3: Add support for all variants
eb2d5e794fb9 thunderbolt: Do not double dequeue a configuration request
b4fac3f172f2 usb: usbtmc: Fix timeout value in get_stb
985961dd2688 serial: jsm: fix NPE during jsm_uart_port_init
e428b7e205ed Bluetooth: hci_qca: move the SoC type check to the right place
4490c7951898 usb: typec: ucsi: fix Clang -Wsign-conversion warning
1a51004aa046 USB: serial: pl2303: add new chip PL2303GC-Q20 and PL2303GT-2AB
393ad978388e usb: storage: Ignore UAS driver for SanDisk 3.2 Gen2 storage device
23179d009cf5 usb: quirks: Add NO_LPM quirk for SanDisk Extreme 55AE
a347664312be Revert "cpufreq: tegra186: Share policy per cluster"
0c60158ff14d block: fix adding folio to bio
3c4fed940db2 PCI/ASPM: Disable L1 before disabling L1 PM Substates
4685153b121e accel/ivpu: Update power island delays
f4deea418499 accel/ivpu: Add initial Panther Lake support
6b482b16f32e rtc: Fix offset calculation for .start_secs < 0
a6a55fe660f8 rtc: Make rtc_time64_to_tm() support dates before 1970
f28fae36bad3 Documentation: ACPI: Use all-string data node references
32b7c46c4dae acpi-cpufreq: Fix nominal_freq units to KHz in get_max_boost_ratio()
614456f1a0fe pinctrl: armada-37xx: set GPIO output value before setting direction
f49c751d6000 pinctrl: armada-37xx: use correct OUTPUT_VAL register for GPIOs > 31
bf49527089ec f2fs: fix to avoid accessing uninitialized curseg
db758487f3dd tracing: Fix compilation warning on arm32
(From OE-Core rev: f51d876fdf243ec4fb0907e870803ecbdb12ca97)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
4.3 KiB
BlitzBasic
80 lines
4.3 KiB
BlitzBasic
KBRANCH ?= "v6.12/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# CVE exclusions
|
|
include recipes-kernel/linux/cve-exclusion.inc
|
|
include recipes-kernel/linux/cve-exclusion_6.12.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v6.12/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v6.12/standard/base"
|
|
KBRANCH:qemumips ?= "v6.12/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v6.12/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v6.12/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v6.12/standard/base"
|
|
KBRANCH:qemux86 ?= "v6.12/standard/base"
|
|
KBRANCH:qemux86.104 ?= "v6.12/standard/base"
|
|
KBRANCH:qemuloongarch64 ?= "v6.12/standard/base"
|
|
KBRANCH:qemumips64 ?= "v6.12/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "588ee9ffcc393af78905cd2e44d54a359d0e500d"
|
|
SRCREV_machine:qemuarm64 ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_machine:qemuloongarch64 ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_machine:qemumips ?= "3610d715bf098ed5d47c98ca9ea395627488ce23"
|
|
SRCREV_machine:qemuppc ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_machine:qemuriscv64 ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_machine:qemuriscv32 ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_machine:qemux86 ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_machine:qemux86-64 ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_machine:qemumips64 ?= "2fd393fbc1b2f8e809b07f4ffb73a4611a569c3d"
|
|
SRCREV_machine ?= "897cf66d25d8a7290eeb899e27456f60fbf203ec"
|
|
SRCREV_meta ?= "bc26c6c6b91fa0e4de4920544cc4aeeb3dedd894"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "e03ced99c437f4a7992b8fa3d97d598f55453fd0"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v6.12/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH};protocol=https \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.12;destsuffix=${KMETA};protocol=https"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "6.12.33"
|
|
|
|
PV = "${LINUX_VERSION}+git"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "arm/versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32|qemuloongarch64)$"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall = " cfg/virtio.scc features/drm-bochs/drm-bochs.scc cfg/net/mdio.scc"
|
|
KERNEL_FEATURES:append:qemux86 = " cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64 = " cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc features/nf_tables/nft_test.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc features/gpio/sim.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("KERNEL_DEBUG", "True", " features/reproducibility/reproducibility.scc features/debug/debug-btf.scc", "", d)}"
|
|
# libteam ptests from meta-oe needs it
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/net/team/team.scc", "", d)}"
|
|
# openl2tp tests from meta-networking needs it
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " cgl/cfg/net/l2tp.scc", "", d)}"
|
|
KERNEL_FEATURES:append:powerpc = " arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64 = " arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64le = " arch/powerpc/powerpc-debug.scc"
|
|
# Do not add debug info for riscv32, it fails during depmod
|
|
# ERROR: modpost: __ex_table+0x17a4 references non-executable section '.debug_loclists'
|
|
# Check again during next major version upgrade
|
|
KERNEL_FEATURES:remove:riscv32 = "features/debug/debug-kernel.scc"
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|