mirror of
https://git.yoctoproject.org/poky
synced 2026-04-25 06:32:12 +02:00
cec8b230cf
A lot of our recipes had short one-line DESCRIPTION values and no SUMMARY value set. In this case it's much better to just set SUMMARY since DESCRIPTION is defaulted from SUMMARY anyway and then the SUMMARY is at least useful. I also took the opportunity to fix up a lot of the new SUMMARY values, making them concisely explain the function of the recipe / package where possible. (From OE-Core rev: b8feee3cf21f70ba4ec3b822d2f596d4fc02a292) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.8 KiB
PHP
46 lines
1.8 KiB
PHP
SUMMARY = "Graphics library for creating hardware-accelerated user interfaces"
|
|
HOMEPAGE = "http://www.clutter-project.org/"
|
|
LICENSE = "LGPLv2.1+"
|
|
|
|
inherit clutter
|
|
|
|
DEPENDS = "pango glib-2.0 json-glib atk udev cogl-1.0"
|
|
PACKAGE_BEFORE_PN += "${PN}-examples"
|
|
AUTOTOOLS_AUXDIR = "${S}/build"
|
|
|
|
EDEPENDS_X11 = "virtual/libx11 libxi libxfixes"
|
|
EDEPENDS_GLX = "virtual/libgl"
|
|
EDEPENDS_EGL = "virtual/egl"
|
|
EDEPENDS_WAYLAND = "wayland libxkbcommon gdk-pixbuf"
|
|
|
|
EDEPENDS_EVDEV = "libxkbcommon"
|
|
ERDEPENDS_EVDEV = "xkeyboard-config"
|
|
|
|
# Disable pretty much everything, override in platform specific set up
|
|
EXTRA_OECONF += "--disable-introspection \
|
|
--disable-quartz-backend \
|
|
--disable-win32-backend \
|
|
--disable-gdk-backend \
|
|
--disable-cex100-backend \
|
|
--disable-tslib-input \
|
|
"
|
|
|
|
PACKAGECONFIG[x11] = "--enable-x11-backend,--disable-x11-backend,${EDEPENDS_X11}"
|
|
PACKAGECONFIG[glx] = ",,${EDEPENDS_X11} ${EDEPENDS_GLX}"
|
|
PACKAGECONFIG[egl] = "--enable-egl-backend,--disable-egl-backend,${EDEPENDS_EGL}"
|
|
PACKAGECONFIG[evdev] = "--enable-evdev-input,--disable-evdev-input,${EDEPENDS_EVDEV},${ERDEPENDS_EVDEV}"
|
|
PACKAGECONFIG[wayland] = "--enable-wayland-backend,--disable-wayland-backend,${EDEPENDS_WAYLAND}"
|
|
PACKAGECONFIG[wayland-compositor] = "--enable-wayland-compositor,--disable-wayland-compositor,wayland"
|
|
|
|
# Default configuration, distros might want to override
|
|
PACKAGECONFIG ??= "${@base_contains('DISTRO_FEATURES', 'wayland', 'wayland', '', d)} \
|
|
${@base_contains('DISTRO_FEATURES', 'x11', 'glx x11', '', d)}"
|
|
|
|
FILES_${PN}-dbg += "${libdir}/clutter/examples/.debug"
|
|
FILES_${PN}-examples = "${libdir}/clutter/examples"
|
|
|
|
do_configure_prepend() {
|
|
# see https://bugzilla.gnome.org/show_bug.cgi?id=661128 for this
|
|
touch -t 200001010000 ${S}/po/clutter-1.0.pot
|
|
}
|