mirror of
https://git.yoctoproject.org/poky
synced 2026-01-29 21:08:42 +01:00
1b94ea8b25
We've been removing PR values from recipes at upgrade time for a while. In general anyone maintaining a binary distro would end up having to curate these themselves so the values in OE-Core aren't really that useful anymore. In many ways it makes sense to clear out the remaining ones (which are mostly for 'config' recipes that are unlikely to increase in PV) and leave a clean slate for anyone implementing a binary distro config. References are left in meta-selftest since the tests there do involve them and their removal upon upgrade. (From OE-Core rev: d4c346e8ab8f3cae25d1b01c7331ed9f6d4f96ef) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
1.7 KiB
BlitzBasic
49 lines
1.7 KiB
BlitzBasic
SUMMARY = "Tools for zmodem/xmodem/ymodem file transfer"
|
|
DESCRIPTION = "Lrzsz is a cosmetically modified zmodem/ymodem/xmodem package built from \
|
|
the public-domain version of Chuck Forsberg's rzsz package. \
|
|
These programs use error correcting protocols ({z,x,y}modem) to send (sz, sx, sb) and \
|
|
receive (rz, rx, rb) files over a dial-in serial port from a variety of programs \
|
|
running under various operating systems. "
|
|
HOMEPAGE = "http://www.ohse.de/uwe/software/lrzsz.html"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
|
|
file://src/lrz.c;beginline=1;endline=10;md5=5276956373ff7d8758837f6399a1045f"
|
|
SECTION = "console/network"
|
|
DEPENDS = ""
|
|
|
|
SRC_URI = "http://www.ohse.de/uwe/releases/lrzsz-${PV}.tar.gz \
|
|
file://autotools-update.patch \
|
|
file://autotools.patch \
|
|
file://makefile.patch \
|
|
file://lrzsz-check-locale.h.patch \
|
|
file://cve-2018-10195.patch \
|
|
file://include.patch \
|
|
file://0001-Fix-cross-compilation-using-autoconf-detected-AR.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "b5ce6a74abc9b9eb2af94dffdfd372a4"
|
|
SRC_URI[sha256sum] = "c28b36b14bddb014d9e9c97c52459852f97bd405f89113f30bee45ed92728ff1"
|
|
|
|
UPSTREAM_CHECK_URI = "http://ohse.de/uwe/software/lrzsz.html"
|
|
|
|
inherit autotools gettext
|
|
|
|
do_install() {
|
|
install -d ${D}${bindir}/
|
|
install -m 0755 src/lrz src/lsz ${D}${bindir}/
|
|
}
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
ALTERNATIVE:${PN} = "rz rx rb sz sx sb"
|
|
|
|
ALTERNATIVE_TARGET[rz] = "${bindir}/lrz"
|
|
ALTERNATIVE_TARGET[rx] = "${bindir}/lrz"
|
|
ALTERNATIVE_TARGET[rb] = "${bindir}/lrz"
|
|
|
|
ALTERNATIVE_TARGET[sz] = "${bindir}/lsz"
|
|
ALTERNATIVE_TARGET[sx] = "${bindir}/lsz"
|
|
ALTERNATIVE_TARGET[sb] = "${bindir}/lsz"
|