mirror of
https://git.yoctoproject.org/poky
synced 2026-03-01 21:09:39 +01:00
3476a49b10
This adds a binconfig-disabled class which can be used by recipes where a -config file is installed but we wish to disable it and just rely on the .pc files instead. Rather than simply deleting it, we make the script "exit 1" so that it can be found in PATH and raise a build error rather than something silently falling back to the build system for example. Rather than randomly finding -config files, this adds in the specification of a list of binconfig scripts which is more deterministic and maintainable moving forward. This patch converts various users in OE-Core to use this, a world build of OE-Core tests out ok with this change. There will likely be issues in other layers however, hence this being a RFT. (From OE-Core rev: 5870bd272b0b077d0826fb900b251884c1c05061) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.3 KiB
PHP
41 lines
1.3 KiB
PHP
SUMMARY = "General purpose cryptographic library based on the code from GnuPG"
|
|
HOMEPAGE = "http://directory.fsf.org/project/libgcrypt/"
|
|
BUGTRACKER = "https://bugs.g10code.com/gnupg/index"
|
|
SECTION = "libs"
|
|
|
|
# helper program gcryptrnd and getrandom are under GPL, rest LGPL
|
|
LICENSE = "GPLv2+ & LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
|
|
file://COPYING.LIB;md5=bbb461211a33b134d42ed5ee802b37ff"
|
|
|
|
DEPENDS = "libgpg-error libcap"
|
|
|
|
SRC_URI = "ftp://ftp.gnupg.org/gcrypt/libgcrypt/libgcrypt-${PV}.tar.gz \
|
|
file://add-pkgconfig-support.patch \
|
|
file://libgcrypt-fix-building-error-with-O2-in-sysroot-path.patch \
|
|
file://fix-ICE-failure-on-mips-with-option-O-and-g.patch \
|
|
"
|
|
|
|
BINCONFIG = "${bindir}/libgcrypt-config"
|
|
|
|
inherit autotools-brokensep texinfo binconfig-disabled pkgconfig
|
|
|
|
EXTRA_OECONF = "--disable-asm --with-capabilities"
|
|
|
|
do_configure_prepend () {
|
|
# Else these could be used in prefernce to those in aclocal-copy
|
|
rm -f ${S}/m4/*.m4
|
|
}
|
|
|
|
# libgcrypt.pc is added locally and thus installed here
|
|
do_install_append() {
|
|
install -d ${D}/${libdir}/pkgconfig
|
|
install -m 0644 ${B}/src/libgcrypt.pc ${D}/${libdir}/pkgconfig/
|
|
}
|
|
|
|
FILES_${PN}-dev += "${bindir}/dumpsexp ${bindir}/hmac256"
|
|
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
BBCLASSEXTEND = "native"
|