mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
8c7cb2d1d2
It failed as below when rerun do_install for tcl: $ bitbake tcl $ bitbake tcl -f -cinstall [snip] | NOTE: make -j 72 DESTDIR=/build/tmp/work/core2-64-wrs-linux/tcl/8.6.10-r0/image install | abort()ing pseudo client by server request. See https://wiki.yoctoproject.org/wiki/Pseudo_Abort for more details on this. | /build/tmp/work/core2-64-wrs-linux/tcl/8.6.10-r0/temp/run.do_install.3490694: line 184: 3499214 Aborted (core dumped) make -j 72 "$@" By default the S is ${WORKDIR}/${BPN}-${PV}, but after unpack, the tcl source [1] unpacked to ${WORKDIR}/${BPN}${PV} and all the files under ${WORKDIR}/${BPN}${PV} are acutally the source files. But the the main Makefile.in is under ${WORKDIR}/${BPN}${PV}/unix for tcl, so there is below logic in tcl recipe: S = "${WORKDIR}/${BPN}${PV}/unix" To adapt the potential pseudo changes, there is a general logic to exclude ${S} from pseudo database in base.bbclass in [2]. That's to say, just the dir ${WORKDIR}/${BPN}${PV}/unix is excluded from the pseudo database. But it's not enough for tcl, we need to exclude the actual source dir ${WORKDIR}/${BPN}${PV} from pseudo database specifically to fix the above do_install failure. [1] https://downloads.sourceforge.net/tcl/tcl8.6.0-src.tar.gz [2] https://git.openembedded.org/openembedded-core/tree/meta/classes/base.bbclass#n396 (From OE-Core rev: 0d835f8069a336fd6bab1058d4e605a81c844212) Signed-off-by: Mingli Yu <mingli.yu@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
107 lines
3.5 KiB
BlitzBasic
107 lines
3.5 KiB
BlitzBasic
SUMMARY = "Tool Command Language"
|
|
HOMEPAGE = "http://tcl.sourceforge.net"
|
|
SECTION = "devel/tcltk"
|
|
|
|
# http://www.tcl.tk/software/tcltk/license.html
|
|
LICENSE = "tcl & BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://../license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
|
file://../compat/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
|
file://../library/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
|
file://../macosx/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
|
file://../tests/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
|
file://../win/license.terms;md5=058f6229798281bbcac4239c788cfa38 \
|
|
"
|
|
|
|
DEPENDS = "tcl-native zlib"
|
|
|
|
BASE_SRC_URI = "${SOURCEFORGE_MIRROR}/tcl/${BPN}${PV}-src.tar.gz \
|
|
file://tcl-add-soname.patch"
|
|
SRC_URI = "${BASE_SRC_URI} \
|
|
file://fix_non_native_build_issue.patch \
|
|
file://fix_issue_with_old_distro_glibc.patch \
|
|
file://no_packages.patch \
|
|
file://tcl-remove-hardcoded-install-path.patch \
|
|
file://alter-includedir.patch \
|
|
file://0001-Fix-abd4abedd2-Failed-to-build-tk-8.6.10-with-cross-.patch;patchdir=.. \
|
|
file://run-ptest \
|
|
"
|
|
SRC_URI[md5sum] = "97c55573f8520bcab74e21bfd8d0aadc"
|
|
SRC_URI[sha256sum] = "5196dbf6638e3df8d5c87b5815c8c2b758496eb6f0e41446596c9a4e638d87ed"
|
|
|
|
SRC_URI_class-native = "${BASE_SRC_URI}"
|
|
|
|
S = "${WORKDIR}/${BPN}${PV}/unix"
|
|
|
|
PSEUDO_IGNORE_PATHS .= ",${WORKDIR}/${BPN}${PV}"
|
|
VER = "${PV}"
|
|
|
|
inherit autotools ptest binconfig update-alternatives
|
|
|
|
EXTRA_OECONF = "--enable-threads --disable-rpath --libdir=${libdir}"
|
|
|
|
do_compile_prepend() {
|
|
echo > ${S}/../compat/fixstrtod.c
|
|
}
|
|
|
|
do_install() {
|
|
autotools_do_install
|
|
oe_runmake 'DESTDIR=${D}' install-private-headers
|
|
ln -sf ./tclsh${VER} ${D}${bindir}/tclsh
|
|
ln -sf tclsh8.6 ${D}${bindir}/tclsh${VER}
|
|
sed -i "s;-L${B};-L${STAGING_LIBDIR};g" tclConfig.sh
|
|
sed -i "s;'${WORKDIR};'${STAGING_INCDIR};g" tclConfig.sh
|
|
install -d ${D}${bindir_crossscripts}
|
|
install -m 0755 tclConfig.sh ${D}${bindir_crossscripts}
|
|
install -m 0755 tclConfig.sh ${D}${libdir}
|
|
for dir in compat generic unix; do
|
|
install -d ${D}${includedir}/${BPN}${VER}/$dir
|
|
install -m 0644 ${S}/../$dir/*.h ${D}${includedir}/${BPN}${VER}/$dir/
|
|
done
|
|
}
|
|
|
|
SYSROOT_DIRS += "${bindir_crossscripts}"
|
|
|
|
PACKAGES =+ "tcl-lib"
|
|
FILES_tcl-lib = "${libdir}/libtcl8.6.so.*"
|
|
FILES_${PN} += "${libdir}/tcl${VER} ${libdir}/tcl8.6 ${libdir}/tcl8"
|
|
FILES_${PN}-dev += "${libdir}/tclConfig.sh ${libdir}/tclooConfig.sh"
|
|
|
|
ALTERNATIVE_${PN}-doc = "Thread.3"
|
|
ALTERNATIVE_LINK_NAME[Thread.3] = "${mandir}/man3/Thread.3"
|
|
|
|
# isn't getting picked up by shlibs code
|
|
RDEPENDS_${PN} += "tcl-lib"
|
|
RDEPENDS_${PN}_class-native = ""
|
|
RDEPENDS_${PN}-ptest += "libgcc"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake tcltest
|
|
}
|
|
|
|
do_install_ptest() {
|
|
cp ${B}/tcltest ${D}${PTEST_PATH}
|
|
cp -r ${S}/../library ${D}${PTEST_PATH}
|
|
cp -r ${S}/../tests ${D}${PTEST_PATH}
|
|
}
|
|
|
|
# Fix some paths that might be used by Tcl extensions
|
|
BINCONFIG_GLOB = "*Config.sh"
|
|
|
|
# Fix the path in sstate
|
|
SSTATE_SCAN_FILES += "*Config.sh"
|
|
|
|
# Cleanup host path from ${libdir}/tclConfig.sh and remove the
|
|
# ${bindir_crossscripts}/tclConfig.sh from target
|
|
PACKAGE_PREPROCESS_FUNCS += "tcl_package_preprocess"
|
|
tcl_package_preprocess() {
|
|
sed -i -e "s;${DEBUG_PREFIX_MAP};;g" \
|
|
-e "s;-L${STAGING_LIBDIR};-L${libdir};g" \
|
|
-e "s;${STAGING_INCDIR};${includedir};g" \
|
|
-e "s;--sysroot=${RECIPE_SYSROOT};;g" \
|
|
${PKGD}${libdir}/tclConfig.sh
|
|
|
|
rm -f ${PKGD}${bindir_crossscripts}/tclConfig.sh
|
|
}
|