mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
1f7ba4ff4e
Release details can be found here: https://github.com/intel/libva/releases/tag/2.6.0 Also switched to meson. (From OE-Core rev: d88764864f670c0d67114f140944aa8857f0b2d5) Signed-off-by: Naveen Saini <naveen.kumar.saini@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.7 KiB
BlitzBasic
44 lines
1.7 KiB
BlitzBasic
SUMMARY = "Video Acceleration (VA) API for Linux"
|
|
DESCRIPTION = "Video Acceleration API (VA API) is a library (libVA) \
|
|
and API specification which enables and provides access to graphics \
|
|
hardware (GPU) acceleration for video processing on Linux and UNIX \
|
|
based operating systems. Accelerated processing includes video \
|
|
decoding, video encoding, subpicture blending and rendering. The \
|
|
specification was originally designed by Intel for its GMA (Graphics \
|
|
Media Accelerator) series of GPU hardware, the API is however not \
|
|
limited to GPUs or Intel specific hardware, as other hardware and \
|
|
manufacturers can also freely use this API for hardware accelerated \
|
|
video decoding."
|
|
|
|
HOMEPAGE = "https://01.org/linuxmedia/vaapi"
|
|
BUGTRACKER = "https://github.com/intel/libva/issues"
|
|
|
|
SECTION = "x11"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2e48940f94acb0af582e5ef03537800f"
|
|
|
|
SRC_URI = "git://github.com/intel/libva.git;branch=v2.6-branch"
|
|
SRCREV = "5f693d9e603e0e83928cec67c30b6ac902d7aa85"
|
|
S = "${WORKDIR}/git"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/intel/libva/releases"
|
|
|
|
DEPENDS = "libdrm virtual/mesa"
|
|
|
|
inherit meson pkgconfig features_check
|
|
|
|
REQUIRED_DISTRO_FEATURES = "opengl"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
PACKAGECONFIG[x11] = "-Dwith_x11=yes, -Dwith_x11=no,virtual/libx11 libxext libxfixes"
|
|
PACKAGECONFIG[wayland] = "-Dwith_wayland=yes, -Dwith_wayland=no,wayland-native wayland"
|
|
|
|
PACKAGES =+ "${PN}-x11 ${PN}-glx ${PN}-wayland"
|
|
|
|
RDEPENDS_${PN}-x11 =+ "${PN}"
|
|
RDEPENDS_${PN}-glx =+ "${PN}-x11"
|
|
|
|
FILES_${PN}-x11 =+ "${libdir}/libva-x11*${SOLIBS}"
|
|
FILES_${PN}-glx =+ "${libdir}/libva-glx*${SOLIBS}"
|
|
FILES_${PN}-wayland =+ "${libdir}/libva-wayland*${SOLIBS}"
|