mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
fe230e1bbf
do_compile error : | ../git/rngd_jitter.c: In function 'rngd_notime_start': | ../git/rngd_jitter.c:56:45: error: invalid use of undefined type 'struct jent_notime_ctx' | 56 | ret = -pthread_attr_init(&thread_ctx->notime_pthread_attr); enable macro JENT_CONF_ENABLE_INTERNAL_TIMER to use struct jent_notime_ctx (From OE-Core rev: e9fac3b6d32262e489992b116275d3eabcc35b4a) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
62 lines
2.2 KiB
BlitzBasic
62 lines
2.2 KiB
BlitzBasic
SUMMARY = "Random number generator daemon"
|
|
DESCRIPTION = "Check and feed random data from hardware device to kernel"
|
|
AUTHOR = "Philipp Rumpf, Jeff Garzik <jgarzik@pobox.com>, \
|
|
Henrique de Moraes Holschuh <hmh@debian.org>"
|
|
HOMEPAGE = "https://github.com/nhorman/rng-tools"
|
|
BUGTRACKER = "https://github.com/nhorman/rng-tools/issues"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
DEPENDS = "sysfsutils openssl"
|
|
|
|
SRC_URI = "git://github.com/nhorman/rng-tools.git;branch=master;protocol=https \
|
|
file://init \
|
|
file://default \
|
|
file://rngd.service \
|
|
"
|
|
SRCREV = "381f69828b782afda574f259c1b7549f48f9bb77"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools update-rc.d systemd pkgconfig
|
|
|
|
EXTRA_OECONF = "--without-rtlsdr"
|
|
|
|
PACKAGECONFIG ??= "libjitterentropy"
|
|
PACKAGECONFIG:libc-musl = "libargp libjitterentropy"
|
|
|
|
PACKAGECONFIG[libargp] = "--with-libargp,--without-libargp,argp-standalone,"
|
|
PACKAGECONFIG[libjitterentropy] = "--enable-jitterentropy,--disable-jitterentropy,libjitterentropy"
|
|
PACKAGECONFIG[libp11] = "--with-pkcs11,--without-pkcs11,libp11 openssl"
|
|
PACKAGECONFIG[nistbeacon] = "--with-nistbeacon,--without-nistbeacon,curl libxml2 openssl"
|
|
|
|
INITSCRIPT_NAME = "rng-tools"
|
|
INITSCRIPT_PARAMS = "start 03 2 3 4 5 . stop 30 0 6 1 ."
|
|
|
|
SYSTEMD_SERVICE:${PN} = "rngd.service"
|
|
|
|
CFLAGS += " -DJENT_CONF_ENABLE_INTERNAL_TIMER "
|
|
|
|
# Refer autogen.sh in rng-tools
|
|
do_configure:prepend() {
|
|
cp ${S}/README.md ${S}/README
|
|
}
|
|
|
|
do_install:append() {
|
|
install -Dm 0644 ${WORKDIR}/default ${D}${sysconfdir}/default/rng-tools
|
|
install -Dm 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/rng-tools
|
|
install -Dm 0644 ${WORKDIR}/rngd.service \
|
|
${D}${systemd_system_unitdir}/rngd.service
|
|
sed -i \
|
|
-e 's,@SYSCONFDIR@,${sysconfdir},g' \
|
|
-e 's,@SBINDIR@,${sbindir},g' \
|
|
${D}${sysconfdir}/init.d/rng-tools \
|
|
${D}${systemd_system_unitdir}/rngd.service
|
|
|
|
if [ "${@bb.utils.contains('PACKAGECONFIG', 'nistbeacon', 'yes', 'no', d)}" = "yes" ]; then
|
|
sed -i \
|
|
-e '/^IPAddressDeny=any/d' \
|
|
-e '/^RestrictAddressFamilies=/ s/$/ AF_INET AF_INET6/' \
|
|
${D}${systemd_system_unitdir}/rngd.service
|
|
fi
|
|
}
|