mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
6377c45653
0001-makedumpfile-replace-hardcode-CFLAGS.patch refreshed for 1.7.6 Changelog: ============ - Fix incorrect page exclusion in exclude_nodata_pages() - s390x: Assume zero value of OS_INFO pointer is valid - Submit physical address to is_phys_addr() - sadump_info: Return empty string instead of NULL - Add ftruncate error handling - Fix failure of free pages exclusion with -x option on Linux 6.10 - fix comment: Mention current logic for vmalloc_start - make reserve_diskspace do nothing for flattened format - Workaround for segfault by "makedumpfile --mem-usage" on PPC64 - Fix wrong exclusion of Slab pages on Linux 6.10-rc1 and later - Fix failure of hugetlb pages exclusion on Linux 6.9 and later - Makefile: Make sbin directory configurable - Update maintainers - ppc64: get vmalloc start address from vmcoreinfo - ppc64: read cur_mmu_type from vmcoreinfo - add PRINTK_CALLER id support to --dump-dmesg option - s390x: uncouple virtual and physical address spaces - s390x: fix virtual vs physical address confusion (From OE-Core rev: 9af31902838cf44febe5977848face501842234e) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
1.7 KiB
BlitzBasic
63 lines
1.7 KiB
BlitzBasic
SUMMARY = "VMcore extraction tool"
|
|
DESCRIPTION = "\
|
|
This program is used to extract a subset of the memory available either \
|
|
via /dev/mem or /proc/vmcore (for crashdumps). It is used to get memory \
|
|
images without extra uneeded information (zero pages, userspace programs, \
|
|
etc). \
|
|
"
|
|
HOMEPAGE = "https://github.com/makedumpfile/makedumpfile"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
|
|
LICENSE = "GPL-2.0-only"
|
|
|
|
SRCBRANCH ?= "master"
|
|
SRCREV = "97a89484e2c960dd64933e1cea7a7248138f8a76"
|
|
|
|
DEPENDS = "bzip2 zlib elfutils xz"
|
|
RDEPENDS:${PN}-tools = "perl ${PN}"
|
|
|
|
# mips/rv32 would not compile.
|
|
COMPATIBLE_HOST:mipsarcho32 = "null"
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
PACKAGES =+ "${PN}-tools"
|
|
FILES:${PN}-tools = "${bindir}/*.pl"
|
|
|
|
SRC_URI = "\
|
|
git://github.com/makedumpfile/makedumpfile;branch=${SRCBRANCH};protocol=https \
|
|
file://0001-makedumpfile-replace-hardcode-CFLAGS.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
|
|
|
|
SECTION = "base"
|
|
|
|
# If we do not specify TARGET, makedumpfile will build for the host but use the
|
|
# target gcc.
|
|
#
|
|
|
|
MAKEDUMPFILE_TARGET ?= "${TARGET_ARCH}"
|
|
MAKEDUMPFILE_TARGET:powerpc = "ppc"
|
|
|
|
EXTRA_OEMAKE = "\
|
|
LINKTYPE=static \
|
|
TARGET=${MAKEDUMPFILE_TARGET} \
|
|
${PACKAGECONFIG_CONFARGS} \
|
|
"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[lzo] = "USELZO=on,USELZO=off,lzo"
|
|
PACKAGECONFIG[snappy] = "USESNAPPY=on,USESNAPPY=off,snappy"
|
|
PACKAGECONFIG[zstd] = "USEZSTD=on,USEZSTD=off,zstd"
|
|
|
|
do_install () {
|
|
mkdir -p ${D}/usr/bin
|
|
install -m 755 ${S}/makedumpfile ${D}/usr/bin
|
|
install -m 755 ${S}/makedumpfile-R.pl ${D}/usr/bin
|
|
|
|
mkdir -p ${D}/etc/
|
|
install -m 644 ${S}/makedumpfile.conf ${D}/etc/makedumpfile.conf.sample
|
|
}
|