mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
2510f1c2e8
* since this commit: commit ad1db93d134db1ec4f6d6598c9741dc13e82e1f3 Author: Anuj Mittal <anuj.mittal@intel.com> Date: Tue May 28 06:32:10 2019 +0800 Subject: Revert "pigz: pigz is not gzip" pigz-native and nativesdk-pigz no longer installs pigz, unpigz, pigzcat, so scripts explicitly depending on pigz-native and calling pigz started to fail. * reverse the logic - all the builds install pigz, unpigz, pigzcat - only the native one installs it as gzip as well * it could be optimized a bit more to create gzip as just a symlink in native case as well, but they are in different directories (pigz in base_bindir and gzip in bindir) and it's only 130kB.. (From OE-Core rev: 112deafd1c144d770b6ec0953911f2adc1cb30dd) Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.7 KiB
BlitzBasic
50 lines
1.7 KiB
BlitzBasic
SUMMARY = "A parallel implementation of gzip"
|
|
DESCRIPTION = "pigz, which stands for parallel implementation of gzip, is a \
|
|
fully functional replacement for gzip that exploits multiple processors and \
|
|
multiple cores to the hilt when compressing data. pigz was written by Mark \
|
|
Adler, and uses the zlib and pthread libraries."
|
|
HOMEPAGE = "http://zlib.net/pigz/"
|
|
SECTION = "console/utils"
|
|
LICENSE = "Zlib & Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://pigz.c;md5=9ae6dee8ceba9610596ed0ada493d142;beginline=7;endline=21"
|
|
|
|
SRC_URI = "http://zlib.net/${BPN}/fossils/${BP}.tar.gz"
|
|
SRC_URI[md5sum] = "def2f6e19d9d8231445adc1349d346df"
|
|
SRC_URI[sha256sum] = "a4f816222a7b4269bd232680590b579ccc72591f1bb5adafcd7208ca77e14f73"
|
|
PROVIDES_class-native += "gzip-native"
|
|
|
|
# Point this at the homepage in case /fossils/ isn't updated
|
|
UPSTREAM_CHECK_URI = "http://zlib.net/${BPN}/"
|
|
UPSTREAM_CHECK_REGEX = "pigz-(?P<pver>.*)\.tar"
|
|
|
|
DEPENDS = "zlib"
|
|
|
|
EXTRA_OEMAKE = "-e MAKEFLAGS="
|
|
|
|
inherit update-alternatives
|
|
|
|
do_install() {
|
|
# Install files into /bin (FHS), which is typical place for gzip
|
|
install -d ${D}${base_bindir}
|
|
install ${B}/pigz ${D}${base_bindir}/pigz
|
|
ln -nsf pigz ${D}${base_bindir}/unpigz
|
|
ln -nsf pigz ${D}${base_bindir}/pigzcat
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
install -d ${D}${bindir}
|
|
install ${B}/pigz ${D}${bindir}/gzip
|
|
ln -nsf gzip ${D}${bindir}/gunzip
|
|
ln -nsf gzip ${D}${bindir}/zcat
|
|
}
|
|
|
|
ALTERNATIVE_PRIORITY = "80"
|
|
ALTERNATIVE_${PN} = "gunzip gzip zcat"
|
|
ALTERNATIVE_${PN}_class-nativesdk = ""
|
|
ALTERNATIVE_LINK_NAME[gunzip] = "${base_bindir}/gunzip"
|
|
ALTERNATIVE_LINK_NAME[gzip] = "${base_bindir}/gzip"
|
|
ALTERNATIVE_LINK_NAME[zcat] = "${base_bindir}/zcat"
|
|
ALTERNATIVE_TARGET = "${base_bindir}/pigz"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|