mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 18:32:20 +02:00
074b2e8c2f
* update to version 3.3
* Remove 0001-zeroconf-Include-fcntl.h.patch since it's
included in v3.3
* Add update-distcc-symlinks into FILES.
(From OE-Core rev: dea59aab5d785d4f892cc26a8ea06eb4a6c554b3)
Signed-off-by: Jackie Huang <jackie.huang@windriver.com>
* Correct upstream SRC_URI and SRCREV to v3.3
* Correct default to fix starting distccd service failed
It caused by upstream commit:
920e8b922a
...
commit 920e8b922addea8c54e68cc29c1416753f532f78
Author: Shawn Landden <slandden@gmail.com>
Date: Mon Feb 26 11:29:14 2018 -0800
daemon: warn when masquerade is not setup
...
Add option --make-me-a-botnet to disable the warning.
* Use localhost to replace 192.168.7.0/24 which is inappropriate for runqemu slirp.
[YOCTO #12741]
Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Ross Burton <ross.burton@intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
70 lines
2.3 KiB
BlitzBasic
70 lines
2.3 KiB
BlitzBasic
SUMMARY = "A parallel build system"
|
|
DESCRIPTION = "distcc is a parallel build system that distributes \
|
|
compilation of C/C++/ObjC code across machines on a network."
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
DEPENDS = "avahi binutils"
|
|
|
|
PACKAGECONFIG ??= "popt"
|
|
PACKAGECONFIG[gtk] = "--with-gtk,--without-gtk --without-gnome,gtk+"
|
|
# use system popt by default
|
|
PACKAGECONFIG[popt] = "--without-included-popt,--with-included-popt,popt"
|
|
|
|
RRECOMMENDS_${PN} = "avahi-daemon"
|
|
|
|
SRC_URI = "git://github.com/distcc/distcc.git \
|
|
file://separatebuilddir.patch \
|
|
file://default \
|
|
file://distccmon-gnome.desktop \
|
|
file://distcc \
|
|
file://distcc.service"
|
|
SRCREV = "002e68b766ccd7ad05551e67d162b71a7a773d0d"
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools pkgconfig update-rc.d useradd systemd
|
|
|
|
EXTRA_OECONF += "--disable-Werror PYTHON='' --disable-pump-mode"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = "--system \
|
|
--home /dev/null \
|
|
--no-create-home \
|
|
--gid nogroup \
|
|
distcc"
|
|
|
|
INITSCRIPT_NAME = "distcc"
|
|
|
|
SYSTEMD_PACKAGES = "${PN}"
|
|
SYSTEMD_SERVICE_${PN} = "distcc.service"
|
|
|
|
do_install() {
|
|
# Improve reproducibility: compress w/o timestamps
|
|
oe_runmake 'DESTDIR=${D}' "GZIP_BIN=gzip -n" install
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
install -d ${D}${sysconfdir}/default
|
|
install -m 0755 ${WORKDIR}/distcc ${D}${sysconfdir}/init.d/
|
|
install -m 0755 ${WORKDIR}/default ${D}${sysconfdir}/default/distcc
|
|
install -d ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${WORKDIR}/distcc.service ${D}${systemd_unitdir}/system
|
|
sed -i -e 's,@BINDIR@,${bindir},g' ${D}${systemd_unitdir}/system/distcc.service
|
|
${DESKTOPINSTALL}
|
|
}
|
|
DESKTOPINSTALL = ""
|
|
DESKTOPINSTALL_libc-glibc () {
|
|
install -d ${D}${datadir}/distcc/
|
|
install -m 0644 ${WORKDIR}/distccmon-gnome.desktop ${D}${datadir}/distcc/
|
|
}
|
|
PACKAGES += "distcc-distmon-gnome"
|
|
|
|
FILES_${PN} = " ${sysconfdir} \
|
|
${bindir}/distcc \
|
|
${bindir}/lsdistcc \
|
|
${bindir}/distccd \
|
|
${bindir}/distccmon-text \
|
|
${sbindir}/update-distcc-symlinks \
|
|
${systemd_unitdir}/system/distcc.service"
|
|
FILES_distcc-distmon-gnome = " ${bindir}/distccmon-gnome \
|
|
${datadir}/distcc"
|