mirror of
https://git.yoctoproject.org/poky
synced 2026-04-28 06:32:34 +02:00
79a3a77680
The gengtype patch we apply to gcc aims to ensure that the build and host config headers don't get confused. We're seeing build failures where both headers have been included, likely due to a race over the configuration files. It seems the gengtype-lex.c file isn't being regenerated when it should and the unconditional inclusion of bconfig.h is resulting in these issues. The fix is therefore to remove the file, forcing its regeneration. [YOCTO #6393] (From OE-Core rev: dd649374b30eb2d9980dce6eae95db0563593ef7) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
132 lines
4.8 KiB
PHP
132 lines
4.8 KiB
PHP
require gcc-multilib-config.inc
|
|
#
|
|
# Build the list of lanaguages to build.
|
|
#
|
|
# These can be overridden by the version specific .inc file.
|
|
|
|
# Java (gcj doesn't work on all architectures)
|
|
JAVA ?= ",java"
|
|
JAVA_arm ?= ""
|
|
JAVA_armeb ?= ""
|
|
JAVA_mipsel ?= ""
|
|
JAVA_sh3 ?= ""
|
|
# gcc 3.x expects 'f77', 4.0 expects 'f95', 4.1 and 4.2 expect 'fortran'
|
|
FORTRAN ?= ",f77"
|
|
LANGUAGES ?= "c,c++${FORTRAN}${JAVA}"
|
|
# disable --enable-target-optspace for powerpc SPE
|
|
# at -Os libgcc.so.1 creates references into
|
|
# hidden symbols in libgcc.a which linker complains
|
|
# when linking shared libraries further in the build like (gnutls)
|
|
|
|
SPECIAL_ARCH_LIST = "powerpc"
|
|
OPTSPACE = '${@bb.utils.contains("SPECIAL_ARCH_LIST", "${TARGET_ARCH}", "", "--enable-target-optspace",d)}'
|
|
|
|
EXTRA_OECONF_BASE ?= ""
|
|
EXTRA_OECONF_PATHS ?= ""
|
|
EXTRA_OECONF_INITIAL ?= ""
|
|
EXTRA_OECONF_INTERMEDIATE ?= ""
|
|
|
|
GCCMULTILIB ?= "--disable-multilib"
|
|
GCCTHREADS ?= "posix"
|
|
|
|
EXTRA_OECONF = "${@['--enable-clocale=generic', ''][d.getVar('USE_NLS', True) != 'no']} \
|
|
--with-gnu-ld \
|
|
--enable-shared \
|
|
--enable-languages=${LANGUAGES} \
|
|
--enable-threads=${GCCTHREADS} \
|
|
${GCCMULTILIB} \
|
|
--enable-c99 \
|
|
--enable-long-long \
|
|
--enable-symvers=gnu \
|
|
--enable-libstdcxx-pch \
|
|
--program-prefix=${TARGET_PREFIX} \
|
|
--without-local-prefix \
|
|
${OPTSPACE} \
|
|
${EXTRA_OECONF_BASE} \
|
|
${EXTRA_OECONF_FPU} \
|
|
${EXTRA_OECONF_PATHS} \
|
|
${@get_gcc_mips_plt_setting(bb, d)} \
|
|
${@get_gcc_multiarch_setting(bb, d)}"
|
|
|
|
export ac_cv_path_SED = 'sed'
|
|
export gcc_cv_collect2_libs = 'none required'
|
|
# We need to set gcc_cv_collect2_libs else there is cross-compilation badness
|
|
# in the config.log files (which might not get generated until do_compile
|
|
# hence being missed by the insane do_configure check).
|
|
|
|
# Build uclibc compilers without cxa_atexit support
|
|
EXTRA_OECONF_append_linux = " --enable-__cxa_atexit"
|
|
EXTRA_OECONF_append_libc-uclibc = " --enable-__cxa_atexit"
|
|
|
|
EXTRA_OECONF_append_mips64 = " --with-abi=64 --with-arch-64=mips64 --with-tune-64=mips64"
|
|
EXTRA_OECONF_append_mips64el = " --with-abi=64 --with-arch-64=mips64 --with-tune-64=mips64"
|
|
|
|
EXTRA_OECONF_FPU ??= ""
|
|
CPPFLAGS = ""
|
|
|
|
# powerpc needs this to comply with the ABI
|
|
EXTRA_OECONF_append_powerpc = " --with-long-double-128"
|
|
EXTRA_OECONF_append_powerpc64 = " --with-long-double-128"
|
|
|
|
SYSTEMHEADERS = "${target_includedir}"
|
|
SYSTEMLIBS = "${target_base_libdir}/"
|
|
SYSTEMLIBS1 = "${target_libdir}/"
|
|
|
|
do_configure_prepend () {
|
|
# teach gcc to find correct target includedir when checking libc ssp support
|
|
mkdir -p ${B}/gcc
|
|
echo "NATIVE_SYSTEM_HEADER_DIR = ${SYSTEMHEADERS}" > ${B}/gcc/t-oe
|
|
cat ${S}/gcc/defaults.h | grep -v "\#endif.*GCC_DEFAULTS_H" > ${B}/gcc/defaults.h.new
|
|
cat >>${B}/gcc/defaults.h.new <<_EOF
|
|
#define NATIVE_SYSTEM_HEADER_DIR "${SYSTEMHEADERS}"
|
|
#define STANDARD_STARTFILE_PREFIX_1 "${SYSTEMLIBS}"
|
|
#define STANDARD_STARTFILE_PREFIX_2 "${SYSTEMLIBS1}"
|
|
#define SYSTEMLIBS_DIR "${SYSTEMLIBS}"
|
|
#endif /* ! GCC_DEFAULTS_H */
|
|
_EOF
|
|
mv ${B}/gcc/defaults.h.new ${B}/gcc/defaults.h
|
|
}
|
|
|
|
python do_preconfigure () {
|
|
import subprocess
|
|
cmd = d.expand('PATH=${PATH} cd ${S} && gnu-configize')
|
|
subprocess.check_output(cmd, stderr=subprocess.STDOUT, shell=True)
|
|
# See 0044-gengtypes.patch, we need to regenerate this file
|
|
bb.utils.remove(d.expand("${S}/gcc/gengtype-lex.c"))
|
|
}
|
|
addtask do_preconfigure after do_patch before do_configure
|
|
do_preconfigure[depends] += "gnu-config-native:do_populate_sysroot autoconf-native:do_populate_sysroot"
|
|
|
|
do_configure () {
|
|
# Setup these vars for cross building only
|
|
# ... because foo_FOR_TARGET apparently gets misinterpreted inside the
|
|
# gcc build stuff when the build is producing a cross compiler - i.e.
|
|
# when the 'current' target is the 'host' system, and the host is not
|
|
# the target (because the build is actually making a cross compiler!)
|
|
if [ "${BUILD_SYS}" != "${HOST_SYS}" ]; then
|
|
export CC_FOR_TARGET="${CC}"
|
|
export GCC_FOR_TARGET="${CC}"
|
|
export CXX_FOR_TARGET="${CXX}"
|
|
export AS_FOR_TARGET="${HOST_PREFIX}as"
|
|
export LD_FOR_TARGET="${HOST_PREFIX}ld"
|
|
export NM_FOR_TARGET="${HOST_PREFIX}nm"
|
|
export AR_FOR_TARGET="${HOST_PREFIX}ar"
|
|
export GFORTRAN_FOR_TARGET="gfortran"
|
|
export RANLIB_FOR_TARGET="${HOST_PREFIX}ranlib"
|
|
fi
|
|
export CC_FOR_BUILD="${BUILD_CC}"
|
|
export CXX_FOR_BUILD="${BUILD_CXX}"
|
|
export CFLAGS_FOR_BUILD="${BUILD_CFLAGS}"
|
|
export CPPFLAGS_FOR_BUILD="${BUILD_CPPFLAGS}"
|
|
export CXXFLAGS_FOR_BUILD="${BUILD_CXXFLAGS}"
|
|
export LDFLAGS_FOR_BUILD="${BUILD_LDFLAGS}"
|
|
export CFLAGS_FOR_TARGET="${TARGET_CFLAGS}"
|
|
export CPPFLAGS_FOR_TARGET="${TARGET_CPPFLAGS}"
|
|
export CXXFLAGS_FOR_TARGET="${TARGET_CXXFLAGS}"
|
|
export LDFLAGS_FOR_TARGET="${TARGET_LDFLAGS}"
|
|
|
|
|
|
oe_runconf
|
|
}
|
|
|