mirror of
https://git.yoctoproject.org/poky
synced 2026-04-30 12:32:12 +02:00
f7e10b532c
This patch changes the result of the "include" test from FAIL to PASS. The test used to fail as the test prerequisite was missing. This was the only test out of 298 that used to fail. (From OE-Core rev: 7e1da2f7c1068cf88424e4af3659d185dbd4167d) Signed-off-by: Juro Bystricky <juro.bystricky@intel.com> Signed-off-by: Ross Burton <ross.burton@intel.com> (cherry picked from commit 3e6bbb81d143919e37cea1549220d27df22080fe) Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.4 KiB
BlitzBasic
50 lines
1.4 KiB
BlitzBasic
SUMMARY = "GNU awk text processing utility"
|
|
DESCRIPTION = "The GNU version of awk, a text processing utility. \
|
|
Awk interprets a special-purpose programming language to do \
|
|
quick and easy text pattern matching and reformatting jobs."
|
|
HOMEPAGE = "https://www.gnu.org/software/gawk/"
|
|
BUGTRACKER = "bug-gawk@gnu.org"
|
|
SECTION = "console/utils"
|
|
|
|
# gawk <= 3.1.5: GPLv2
|
|
# gawk >= 3.1.6: GPLv3
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
DEPENDS += "readline"
|
|
|
|
PACKAGECONFIG[mpfr] = "--with-mpfr,--without-mpfr, mpfr"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/gawk/gawk-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
file://test-arrayind1-Remove-hashbang-line.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "f20c94ca51b6ebfc9bffb90f95c8ffbb"
|
|
SRC_URI[sha256sum] = "8c03080e2b5a56263e8783f6f1f306398d4591be18254041f3f547efef944d35"
|
|
|
|
inherit autotools gettext texinfo update-alternatives
|
|
|
|
FILES_${PN} += "${datadir}/awk"
|
|
FILES_${PN}-dev += "${libdir}/${BPN}/*.la"
|
|
|
|
ALTERNATIVE_${PN} = "awk"
|
|
ALTERNATIVE_TARGET[awk] = "${bindir}/gawk"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
do_install_append() {
|
|
# remove the link since we don't package it
|
|
rm ${D}${bindir}/awk
|
|
}
|
|
|
|
inherit ptest
|
|
|
|
do_install_ptest() {
|
|
mkdir ${D}${PTEST_PATH}/test
|
|
for i in `grep -vE "@|^$|#|Gt-dummy" ${S}/test/Maketests |awk -F: '{print $1}'` Maketests inclib.awk; \
|
|
do cp ${S}/test/$i* ${D}${PTEST_PATH}/test; \
|
|
done
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|