mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 12:32:13 +02:00
4cac662d7d
Drop backports: 48fff0a2af3f62acd446ebec8081b039b72caad8.patch 7c5fd25119a495009ea62f79e5daec34cc464628.patch 0001-analyze-resolve-executable-path-if-it-is-relative.patch 0001-analyze-resolve-executable-path-if-it-is-relative.patch Drop 0027-proc-dont-trigger-mount-error-with-invalid-options-o.patch as difficult to rebase; please resend if you feel strongly that it is needed. Rebase the big pile of musl patches. (From OE-Core rev: e8dd5a36bf2f1e645fb2ff15eb3b5e97c04776e6) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
2.0 KiB
BlitzBasic
71 lines
2.0 KiB
BlitzBasic
require systemd.inc
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemd:"
|
|
|
|
require conf/image-uefi.conf
|
|
|
|
DEPENDS = "intltool-native libcap util-linux gnu-efi gperf-native"
|
|
|
|
inherit meson pkgconfig gettext
|
|
inherit deploy
|
|
|
|
LDFLAGS_prepend = "${@ " ".join(d.getVar('LD').split()[1:])} "
|
|
|
|
do_write_config[vardeps] += "CC OBJCOPY"
|
|
do_write_config_append() {
|
|
cat >${WORKDIR}/meson-${PN}.cross <<EOF
|
|
[binaries]
|
|
efi_cc = ${@meson_array('CC', d)}
|
|
objcopy = ${@meson_array('OBJCOPY', d)}
|
|
EOF
|
|
}
|
|
|
|
EXTRA_OEMESON += "-Defi=true \
|
|
-Dgnu-efi=true \
|
|
-Defi-includedir=${STAGING_INCDIR}/efi \
|
|
-Defi-libdir=${STAGING_LIBDIR} \
|
|
-Defi-ld=${@ d.getVar('LD').split()[0]} \
|
|
-Dman=false \
|
|
--cross-file ${WORKDIR}/meson-${PN}.cross \
|
|
"
|
|
|
|
# install to the image as boot*.efi if its the EFI_PROVIDER,
|
|
# otherwise install as the full name.
|
|
# This allows multiple bootloaders to coexist in a single image.
|
|
python __anonymous () {
|
|
import re
|
|
target = d.getVar('TARGET_ARCH')
|
|
prefix = "" if d.getVar('EFI_PROVIDER') == "systemd-boot" else "systemd-"
|
|
systemdimage = prefix + d.getVar("EFI_BOOT_IMAGE")
|
|
d.setVar("SYSTEMD_BOOT_IMAGE", systemdimage)
|
|
prefix = "systemd-" if prefix == "" else ""
|
|
d.setVar("SYSTEMD_BOOT_IMAGE_PREFIX", prefix)
|
|
}
|
|
|
|
FILES_${PN} = "${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE}"
|
|
|
|
RDEPENDS_${PN} += "virtual/systemd-bootconf"
|
|
|
|
# Imported from the old gummiboot recipe
|
|
TUNE_CCARGS_remove = "-mfpmath=sse"
|
|
|
|
COMPATIBLE_HOST = "(aarch64.*|arm.*|x86_64.*|i.86.*)-linux"
|
|
COMPATIBLE_HOST_x86-x32 = "null"
|
|
|
|
do_compile() {
|
|
ninja \
|
|
src/boot/efi/${SYSTEMD_BOOT_IMAGE_PREFIX}${SYSTEMD_BOOT_IMAGE} \
|
|
src/boot/efi/linux${EFI_ARCH}.efi.stub
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${EFI_FILES_PATH}
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${D}${EFI_FILES_PATH}/${SYSTEMD_BOOT_IMAGE}
|
|
}
|
|
|
|
do_deploy () {
|
|
install ${B}/src/boot/efi/systemd-boot*.efi ${DEPLOYDIR}
|
|
install ${B}/src/boot/efi/linux*.efi.stub ${DEPLOYDIR}
|
|
}
|
|
|
|
addtask deploy before do_build after do_compile
|