mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
459c053917
(From OE-Core rev: 73ebdcaedde460108f98971f037e50e9b15c9f0c) (From OE-Core rev: 3bcc575367ac2519fc76fbd3d1d7f0223c059b96) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
88 lines
3.0 KiB
BlitzBasic
88 lines
3.0 KiB
BlitzBasic
SUMMARY = "Common CA certificates"
|
|
DESCRIPTION = "This package includes PEM files of CA certificates to allow \
|
|
SSL-based applications to check for the authenticity of SSL connections. \
|
|
This derived from Debian's CA Certificates."
|
|
HOMEPAGE = "http://packages.debian.org/sid/ca-certificates"
|
|
SECTION = "misc"
|
|
LICENSE = "GPL-2.0+ & MPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://debian/copyright;md5=aeb420429b1659507e0a5a1b123e8308"
|
|
|
|
# This is needed to ensure we can run the postinst at image creation time
|
|
DEPENDS = ""
|
|
DEPENDS_class-native = "openssl-native"
|
|
DEPENDS_class-nativesdk = "openssl-native"
|
|
# Need c_rehash from openssl and run-parts from debianutils
|
|
PACKAGE_WRITE_DEPS += "openssl-native debianutils-native"
|
|
|
|
SRCREV = "c28799b138b044c963d24c4a69659b6e5486e3be"
|
|
|
|
SRC_URI = "git://salsa.debian.org/debian/ca-certificates.git;protocol=https \
|
|
file://0002-update-ca-certificates-use-SYSROOT.patch \
|
|
file://0001-update-ca-certificates-don-t-use-Debianisms-in-run-p.patch \
|
|
file://update-ca-certificates-support-Toybox.patch \
|
|
file://default-sysroot.patch \
|
|
file://sbindir.patch \
|
|
file://0003-update-ca-certificates-use-relative-symlinks-from-ET.patch \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit allarch
|
|
|
|
EXTRA_OEMAKE = "\
|
|
'CERTSDIR=${datadir}/ca-certificates' \
|
|
'SBINDIR=${sbindir}' \
|
|
"
|
|
|
|
do_compile_prepend() {
|
|
oe_runmake clean
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${datadir}/ca-certificates \
|
|
${D}${sysconfdir}/ssl/certs \
|
|
${D}${sysconfdir}/ca-certificates/update.d
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
|
|
install -d ${D}${mandir}/man8
|
|
install -m 0644 sbin/update-ca-certificates.8 ${D}${mandir}/man8/
|
|
|
|
install -d ${D}${sysconfdir}
|
|
{
|
|
echo "# Lines starting with # will be ignored"
|
|
echo "# Lines starting with ! will remove certificate on next update"
|
|
echo "#"
|
|
find ${D}${datadir}/ca-certificates -type f -name '*.crt' | \
|
|
sed 's,^${D}${datadir}/ca-certificates/,,'
|
|
} >${D}${sysconfdir}/ca-certificates.conf
|
|
}
|
|
|
|
do_install_append_class-target () {
|
|
sed -i -e 's,/etc/,${sysconfdir}/,' \
|
|
-e 's,/usr/share/,${datadir}/,' \
|
|
-e 's,/usr/local,${prefix}/local,' \
|
|
${D}${sbindir}/update-ca-certificates \
|
|
${D}${mandir}/man8/update-ca-certificates.8
|
|
}
|
|
|
|
pkg_postinst_${PN}_class-target () {
|
|
SYSROOT="$D" $D${sbindir}/update-ca-certificates
|
|
}
|
|
|
|
CONFFILES_${PN} += "${sysconfdir}/ca-certificates.conf"
|
|
|
|
# Rather than make a postinst script that works for both target and nativesdk,
|
|
# we just run update-ca-certificate from do_install() for nativesdk.
|
|
CONFFILES_${PN}_append_class-nativesdk = " ${sysconfdir}/ssl/certs/ca-certificates.crt"
|
|
do_install_append_class-nativesdk () {
|
|
SYSROOT="${D}${SDKPATHNATIVE}" ${D}${sbindir}/update-ca-certificates
|
|
}
|
|
|
|
do_install_append_class-native () {
|
|
SYSROOT="${D}${base_prefix}" ${D}${sbindir}/update-ca-certificates
|
|
}
|
|
|
|
RDEPENDS_${PN} += "openssl"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|