mirror of
https://git.yoctoproject.org/poky
synced 2026-02-28 12:29:40 +01:00
bd3792a7ad
Building the LLVM projects often means using the TableGen tools (llvm-tblgen etc). We currently build them as part of clang-native, but I am teasing the clang recipe into its component parts and having to build llvm-native or lldb-native simply for one tool isn't ideal. Instead, add a native recipe that simply builds the tablegen binaries for llvm, clang, and lldb (From OE-Core rev: fbf63e03fe09ca74022c9d06442b4f1021b71d57) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
28 lines
825 B
BlitzBasic
28 lines
825 B
BlitzBasic
SUMMARY = "LLVM TableGen binaries, for the build host"
|
|
SECTION = "devel"
|
|
|
|
# Building the LLVM projects often means using the TableGen tools (llvm-tblgen,
|
|
# etc). We could build these as part of llvm-native, but there are cases where
|
|
# this would be overkill. For example, building a target LLDB needs native
|
|
# tablegen binaries and a target libllvm so having to build a complete native
|
|
# llvm is not needed.
|
|
|
|
require common-clang.inc
|
|
require common-source.inc
|
|
|
|
inherit cmake pkgconfig native
|
|
|
|
OECMAKE_SOURCEPATH = "${S}/llvm"
|
|
|
|
EXTRA_OECMAKE += "-DCMAKE_BUILD_TYPE=Release -DLLVM_ENABLE_PROJECTS='llvm;clang;lldb'"
|
|
|
|
BINARIES = "llvm-min-tblgen llvm-tblgen clang-tblgen lldb-tblgen"
|
|
|
|
OECMAKE_TARGET_COMPILE = "${BINARIES}"
|
|
|
|
do_install() {
|
|
for f in ${BINARIES}; do
|
|
install -D ${B}/bin/$f ${D}${bindir}/$f
|
|
done
|
|
}
|