mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 18:02:12 +01:00
4b41d9072a
The busybox-syslog rrecomends is proving tricky as it gets pulled in early and there are conflicts between its use of update-alternatives and busybox needing to provide those things. We already have recipes using BAD_RRECOMMENDS to remove this dependency, it probably makes sense to spell it out explicitly and allow it to be overridden more easily. This patch does this, dropping the now unneeded BAD_RRECOMMENDS. It preserves the dependency as a recommendation for now, further cleanup may allow simplication of that. This unbreaks certain build failures on the autobuilder, more as a workaround but is a change we probably want to make anyway. (From OE-Core rev: 544ade2d78f1375d9e93d6bf5842d857ddaf3530) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.6 KiB
BlitzBasic
51 lines
1.6 KiB
BlitzBasic
#
|
|
# Copyright (C) 2007 OpenedHand Ltd.
|
|
#
|
|
|
|
SUMMARY = "Minimal boot requirements"
|
|
DESCRIPTION = "The minimal set of packages required to boot the system"
|
|
PR = "r17"
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
inherit packagegroup
|
|
|
|
#
|
|
# Set by the machine configuration with packages essential for device bootup
|
|
#
|
|
MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
|
|
MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
|
|
|
|
# Distro can override the following VIRTUAL-RUNTIME providers:
|
|
VIRTUAL-RUNTIME_dev_manager ?= "udev"
|
|
VIRTUAL-RUNTIME_login_manager ?= "busybox"
|
|
VIRTUAL-RUNTIME_init_manager ?= "sysvinit"
|
|
VIRTUAL-RUNTIME_initscripts ?= "initscripts"
|
|
VIRTUAL-RUNTIME_keymaps ?= "keymaps"
|
|
|
|
EFI_PROVIDER ??= "grub-efi"
|
|
|
|
SYSVINIT_SCRIPTS = "${@bb.utils.contains('MACHINE_FEATURES', 'rtc', '${VIRTUAL-RUNTIME_base-utils-hwclock}', '', d)} \
|
|
modutils-initscripts \
|
|
init-ifupdown \
|
|
${VIRTUAL-RUNTIME_initscripts} \
|
|
"
|
|
|
|
RDEPENDS_${PN} = "\
|
|
base-files \
|
|
base-passwd \
|
|
${VIRTUAL-RUNTIME_base-utils} \
|
|
${@bb.utils.contains("DISTRO_FEATURES", "sysvinit", "${SYSVINIT_SCRIPTS}", "", d)} \
|
|
${@bb.utils.contains("MACHINE_FEATURES", "keyboard", "${VIRTUAL-RUNTIME_keymaps}", "", d)} \
|
|
${@bb.utils.contains("MACHINE_FEATURES", "efi", "${EFI_PROVIDER} kernel", "", d)} \
|
|
netbase \
|
|
${VIRTUAL-RUNTIME_login_manager} \
|
|
${VIRTUAL-RUNTIME_init_manager} \
|
|
${VIRTUAL-RUNTIME_dev_manager} \
|
|
${VIRTUAL-RUNTIME_update-alternatives} \
|
|
${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
|
|
|
|
RRECOMMENDS_${PN} = "\
|
|
${VIRTUAL-RUNTIME_base-utils-syslog} \
|
|
${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
|