mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 01:06:37 +01:00
3e903cb42f
"yocto-compat-layer.py --machines" showed that shared packages like gcc-cross-powerpc64 have a sstate signature that depends on TUNEFLAGS. As a result, there are unnecessary rebuilds and potential conflicts in a multiconfig. That's due to the way how TARGET_ARCH is set. Richard Purdie suggested setting TARGET_ARCH[vardepvalue] as fix, which works. It would be shorter to do that in cross.bbclass instead of repeating the relevant line in different recipes, but Richard was concerned about potential side-effects in other usages of cross.bbclass. TARGET_GOARM as used in go.inc is still causing signature differences for go-cross-powerpc64 and machines b4420qds-64b and p5020ds-64b. This needs further investigation. (From OE-Core rev: 39bfa0dd3237cbca47e7fca1075d521f9d073f25) Signed-off-by: Patrick Ohly <patrick.ohly@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.6 KiB
PHP
39 lines
1.6 KiB
PHP
inherit cross
|
|
PROVIDES = "virtual/${TARGET_PREFIX}binutils"
|
|
|
|
PN = "binutils-cross-${TARGET_ARCH}"
|
|
BPN = "binutils"
|
|
|
|
# Ignore how TARGET_ARCH is computed.
|
|
TARGET_ARCH[vardepvalue] = "${TARGET_ARCH}"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
INHIBIT_AUTOTOOLS_DEPS = "1"
|
|
|
|
SRC_URI += "file://0002-binutils-cross-Do-not-generate-linker-script-directo.patch"
|
|
|
|
# Specify lib-path else we use a load of search dirs which we don't use
|
|
# and mean the linker scripts have to be relocated.
|
|
EXTRA_OECONF += "--with-sysroot=${STAGING_DIR_TARGET} \
|
|
--disable-install-libbfd \
|
|
--enable-poison-system-directories \
|
|
--with-lib-path==${target_base_libdir}:=${target_libdir} \
|
|
"
|
|
do_install () {
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
|
|
# We don't really need these, so we'll remove them...
|
|
rm -rf ${D}${STAGING_DIR_NATIVE}${libdir_native}/libiberty.a
|
|
rm -rf ${D}${STAGING_DIR_NATIVE}${prefix_native}/${TARGET_SYS}
|
|
rm -rf ${D}${STAGING_DIR_NATIVE}${prefix_native}/lib/ldscripts
|
|
rm -rf ${D}${STAGING_DIR_NATIVE}${prefix_native}/share/info
|
|
rm -rf ${D}${STAGING_DIR_NATIVE}${prefix_native}/share/locale
|
|
rm -rf ${D}${STAGING_DIR_NATIVE}${prefix_native}/share/man
|
|
rmdir ${D}${STAGING_DIR_NATIVE}${prefix_native}/share || :
|
|
rmdir ${D}${STAGING_DIR_NATIVE}${prefix_native}/${libdir}/gcc-lib || :
|
|
rmdir ${D}${STAGING_DIR_NATIVE}${prefix_native}/${libdir}64/gcc-lib || :
|
|
rmdir ${D}${STAGING_DIR_NATIVE}${prefix_native}/${libdir} || :
|
|
rmdir ${D}${STAGING_DIR_NATIVE}${prefix_native}/${libdir}64 || :
|
|
rmdir ${D}${STAGING_DIR_NATIVE}${prefix_native}/${prefix} || :
|
|
}
|