mirror of
https://git.yoctoproject.org/poky
synced 2026-02-12 11:43:04 +01:00
563a020870
These functions were moved to meta/lib/oe in 2010 and the base_* functions in utils.bbclass were intended to be a short-term compatibility layer. They're still used in a few places, so update the callers to use the new functions. (From OE-Core rev: c97acbd034532895ce57c6717ed1b3ccc7900b0d) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.2 KiB
PHP
43 lines
1.2 KiB
PHP
require libgcc-common.inc
|
|
|
|
DEPENDS = "virtual/${TARGET_PREFIX}gcc virtual/${TARGET_PREFIX}g++"
|
|
|
|
do_install_append_class-target () {
|
|
if [ "${TCLIBC}" != "glibc" ]; then
|
|
case "${TARGET_OS}" in
|
|
"linux-musl" | "linux-*spe") extra_target_os="linux";;
|
|
"linux-musleabi") extra_target_os="linux-gnueabi";;
|
|
*) extra_target_os="linux";;
|
|
esac
|
|
ln -s ${TARGET_SYS} ${D}${libdir}/${TARGET_ARCH}${TARGET_VENDOR}-$extra_target_os
|
|
fi
|
|
}
|
|
|
|
PACKAGES = "\
|
|
${PN} \
|
|
${PN}-dev \
|
|
${PN}-dbg \
|
|
"
|
|
|
|
# All libgcc source is marked with the exception.
|
|
#
|
|
LICENSE_${PN} = "GPL-3.0-with-GCC-exception"
|
|
LICENSE_${PN}-dev = "GPL-3.0-with-GCC-exception"
|
|
LICENSE_${PN}-dbg = "GPL-3.0-with-GCC-exception"
|
|
|
|
|
|
FILES_${PN}-dev = "\
|
|
${base_libdir}/libgcc*.so \
|
|
${@oe.utils.conditional('BASETARGET_SYS', '${TARGET_SYS}', '', '${libdir}/${BASETARGET_SYS}', d)} \
|
|
${libdir}/${TARGET_SYS}/${BINV}* \
|
|
${libdir}/${TARGET_ARCH}${TARGET_VENDOR}* \
|
|
"
|
|
|
|
do_package[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
|
|
INSANE_SKIP_${PN}-dev = "staticdev"
|
|
|