mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 17:26:36 +01:00
e234be1bef
Update SQLite3 from 3.25.2 to 3.25.3 to fix following issues: * Disallow the use of window functions in the recursive part of a CTE. * Fix the behavior of typeof() and length() on virtual tables. * Strengthen defenses against deliberately corrupted database files. * Fix a problem in the query planner that results when a row-value expression is used with a PRIMARY KEY with redundant columns. * Fix the query planner so that it works correctly for IS NOT NULL operators in the ON clause of a LEFT JOIN with the SQLITE_ENABLE_STAT4 compile-time option. Also introduce PACKAGECONFIG tunables to enable/disable e.g. index and search functions to allow shrinking the library for very small targets. (From OE-Core rev: d533ad9b93383a8d721b72b4030b112a3799d559) Signed-off-by: Jens Rehsack <sno@netbsd.org> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
64 lines
2.0 KiB
PHP
64 lines
2.0 KiB
PHP
SUMMARY = "Embeddable SQL database engine"
|
|
HOMEPAGE = "http://www.sqlite.org"
|
|
SECTION = "libs"
|
|
|
|
PE = "3"
|
|
|
|
def sqlite_download_version(d):
|
|
pvsplit = d.getVar('PV').split('.')
|
|
if len(pvsplit) < 4:
|
|
pvsplit.append('0')
|
|
return pvsplit[0] + ''.join([part.rjust(2,'0') for part in pvsplit[1:]])
|
|
|
|
SQLITE_PV = "${@sqlite_download_version(d)}"
|
|
|
|
S = "${WORKDIR}/sqlite-autoconf-${SQLITE_PV}"
|
|
|
|
UPSTREAM_CHECK_URI = "http://www.sqlite.org/"
|
|
UPSTREAM_CHECK_REGEX = "releaselog/(?P<pver>(\d+[\.\-_]*)+)\.html"
|
|
|
|
CVE_PRODUCT = "sqlite"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
# enable those which are enabled by default in configure
|
|
PACKAGECONFIG ?= "fts4 fts5 json1 rtree dyn_ext"
|
|
PACKAGECONFIG_class-native ?= "fts4 fts5 json1 rtree dyn_ext"
|
|
|
|
PACKAGECONFIG[editline] = "--enable-editline,--disable-editline,libedit"
|
|
PACKAGECONFIG[readline] = "--enable-readline,--disable-readline,readline ncurses"
|
|
PACKAGECONFIG[fts3] = "--enable-fts3,--disable-fts3"
|
|
PACKAGECONFIG[fts4] = "--enable-fts4,--disable-fts4"
|
|
PACKAGECONFIG[fts5] = "--enable-fts5,--disable-fts5"
|
|
PACKAGECONFIG[json1] = "--enable-json1,--disable-json1"
|
|
PACKAGECONFIG[rtree] = "--enable-rtree,--disable-rtree"
|
|
PACKAGECONFIG[session] = "--enable-session,--disable-session"
|
|
PACKAGECONFIG[dyn_ext] = "--enable-dynamic-extensions,--disable-dynamic-extensions"
|
|
|
|
EXTRA_OECONF = " \
|
|
--enable-shared \
|
|
--enable-threadsafe \
|
|
--disable-static-shell \
|
|
"
|
|
|
|
CFLAGS_append = " -fPIC"
|
|
|
|
# pread() is in POSIX.1-2001 so any reasonable system must surely support it
|
|
CFLAGS += "-DUSE_PREAD"
|
|
|
|
# Provide column meta-data API
|
|
CFLAGS += "-DSQLITE_ENABLE_COLUMN_METADATA"
|
|
|
|
PACKAGES = "lib${BPN} lib${BPN}-dev lib${BPN}-doc ${PN}-dbg lib${BPN}-staticdev ${PN}"
|
|
|
|
FILES_${PN} = "${bindir}/*"
|
|
FILES_lib${BPN} = "${libdir}/*.so.*"
|
|
FILES_lib${BPN}-dev = "${libdir}/*.la ${libdir}/*.so \
|
|
${libdir}/pkgconfig ${includedir}"
|
|
FILES_lib${BPN}-doc = "${docdir} ${mandir} ${infodir}"
|
|
FILES_lib${BPN}-staticdev = "${libdir}/lib*.a"
|
|
|
|
AUTO_LIBNAME_PKGS = "${MLPREFIX}lib${BPN}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|