mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 08:48:45 +01:00
2d1d8e91b2
This is the core of one of the "new build system" tools--hosted officially as part of the pypa (Python Packaging Authority) repositories--it is an increasingly common build tool (e.g. typing_extensions and tomli) as declared in pyproject.toml for said packages. This package provides a very simple bootstrapping method that builds the source tarball (build_sdist) and a wheel (build_wheel). Bootstrap -native by simply unzipping the wheel to PYTHON_SITEPACKAGES_DIR. Use pip to install the wheel for class-target. Wheels are the official vehicle for delivering Python packages now. Eggs (egg-info) are deprecated and will increasingly go away. [YOCTO #14638] (From OE-Core rev: 18717181e4a893fd7c309eb75443a868ec4e83eb) Signed-off-by: Tim Orling <tim.orling@konsulko.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.1 KiB
BlitzBasic
42 lines
1.1 KiB
BlitzBasic
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=41eb78fa8a872983a882c694a8305f08"
|
|
|
|
SRC_URI[sha256sum] = "b1464e006df4df4c8eeb37671c0e0ce66e1d04e4a36d91b702f180a25fde3c11"
|
|
|
|
inherit python3native python3-dir pypi setuptools3-base
|
|
|
|
DEPENDS:append:class-target = " python3-pip-native"
|
|
DEPENDS:append:class-native = " unzip-native"
|
|
|
|
# We need the full flit tarball
|
|
PYPI_PACKAGE = "flit"
|
|
|
|
do_compile () {
|
|
nativepython3 flit_core/build_dists.py
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
PYTHONPATH=${D}${PYTHON_SITEPACKAGES_DIR} \
|
|
nativepython3 -m pip install -vvvv --no-deps --no-index --target ${D}${PYTHON_SITEPACKAGES_DIR} ./flit_core/dist/flit_core-${PV}-py3-none-any.whl
|
|
}
|
|
|
|
do_install:class-native () {
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
unzip -d ${D}${PYTHON_SITEPACKAGES_DIR} ./flit_core/dist/flit_core-${PV}-py3-none-any.whl
|
|
}
|
|
|
|
FILES:${PN} += "\
|
|
${PYTHON_SITEPACKAGES_DIR}/flit_core/* \
|
|
${PYTHON_SITEPACKAGES_DIR}/flit_core-${PV}.dist-info/* \
|
|
"
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
FILES:${PN}-tests += "\
|
|
${PYTHON_SITEPACKAGES_DIR}/flit_core/tests/* \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|
|
|