mirror of
https://git.yoctoproject.org/poky
synced 2026-03-03 13:59:40 +01:00
6bc15eb887
File name mapping was added to bison, but needs to be applied in more cases. Add a patch to enable file name mapping for symbols (From OE-Core rev: a47a39a70918f18f092d0f38313f015ee79cadbf) Signed-off-by: Joshua Watt <JPEWhacker@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 5a213506377b0db4e88ca094215eadf08c21a2e1) Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.4 KiB
BlitzBasic
39 lines
1.4 KiB
BlitzBasic
SUMMARY = "GNU Project parser generator (yacc replacement)"
|
|
DESCRIPTION = "Bison is a general-purpose parser generator that converts an annotated context-free grammar into \
|
|
an LALR(1) or GLR parser for that grammar. Bison is upward compatible with Yacc: all properly-written Yacc \
|
|
grammars ought to work with Bison with no change. Anyone familiar with Yacc should be able to use Bison with \
|
|
little trouble."
|
|
HOMEPAGE = "http://www.gnu.org/software/bison/"
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
SECTION = "devel"
|
|
DEPENDS = "bison-native flex-native"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/bison/bison-${PV}.tar.xz \
|
|
file://add-with-bisonlocaledir.patch \
|
|
file://0001-Use-mapped-file-name-for-symbols.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "7948d193104d979c0fb0294a1854c73c89d72ae41acfc081826142578a78a91b"
|
|
|
|
# No point in hardcoding path to m4, just use PATH
|
|
EXTRA_OECONF += "M4=m4"
|
|
|
|
inherit autotools gettext texinfo
|
|
|
|
# The automatic m4 path detection gets confused, so force the right value
|
|
acpaths = "-I ./m4"
|
|
|
|
do_compile_prepend() {
|
|
for i in mfcalc calc++ rpcalc; do mkdir -p ${B}/examples/$i; done
|
|
}
|
|
|
|
do_install_append_class-native() {
|
|
create_wrapper ${D}/${bindir}/bison \
|
|
BISON_PKGDATADIR=${STAGING_DATADIR_NATIVE}/bison
|
|
}
|
|
do_install_append_class-nativesdk() {
|
|
create_wrapper ${D}/${bindir}/bison \
|
|
BISON_PKGDATADIR=${datadir}/bison
|
|
}
|
|
BBCLASSEXTEND = "native nativesdk"
|