mirror of
https://git.yoctoproject.org/poky
synced 2026-02-28 12:29:40 +01:00
2c69b69d69
(From OE-Core rev: cf874a13b7bac44f5ff2ad98eb7a87f18c16f9b0) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 2b724599e29808014f5d9c1fdc70d20abab9b3e5) Signed-off-by: Lee Chee Yang <chee.yang.lee@intel.com> Signed-off-by: Anuj Mittal <anuj.mittal@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.3 KiB
BlitzBasic
47 lines
1.3 KiB
BlitzBasic
# This recipe is for bootstrapping our go-cross from a prebuilt binary of Go from golang.org.
|
|
|
|
SUMMARY = "Go programming language compiler (upstream binary for bootstrap)"
|
|
HOMEPAGE = " http://golang.org/"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5d4950ecb7b26d2c5e4e7b4e0dd74707"
|
|
|
|
PROVIDES = "go-native"
|
|
|
|
SRC_URI = "https://dl.google.com/go/go${PV}.${BUILD_GOOS}-${BUILD_GOARCH}.tar.gz;name=go_${BUILD_GOTUPLE}"
|
|
SRC_URI[go_linux_amd64.sha256sum] = "d3379c32a90fdf9382166f8f48034c459a8cc433730bc9476d39d9082c94583b"
|
|
SRC_URI[go_linux_arm64.sha256sum] = "0e31ea4bf53496b0f0809730520dee98c0ae5c530f3701a19df0ba0a327bf3d2"
|
|
|
|
UPSTREAM_CHECK_URI = "https://golang.org/dl/"
|
|
UPSTREAM_CHECK_REGEX = "go(?P<pver>\d+(\.\d+)+)\.linux"
|
|
|
|
S = "${WORKDIR}/go"
|
|
|
|
inherit goarch native
|
|
|
|
do_compile() {
|
|
:
|
|
}
|
|
|
|
make_wrapper() {
|
|
rm -f ${D}${bindir}/$1
|
|
cat <<END >${D}${bindir}/$1
|
|
#!/bin/bash
|
|
here=\`dirname \$0\`
|
|
export GOROOT="${GOROOT:-\`readlink -f \$here/../lib/go\`}"
|
|
\$here/../lib/go/bin/$1 "\$@"
|
|
END
|
|
chmod +x ${D}${bindir}/$1
|
|
}
|
|
|
|
do_install() {
|
|
find ${S} -depth -type d -name testdata -exec rm -rf {} +
|
|
|
|
install -d ${D}${bindir} ${D}${libdir}/go
|
|
cp --preserve=mode,timestamps -R ${S}/ ${D}${libdir}/
|
|
|
|
for f in ${S}/bin/*
|
|
do
|
|
make_wrapper `basename $f`
|
|
done
|
|
}
|