mirror of
https://git.yoctoproject.org/poky
synced 2026-02-27 11:59:40 +01:00
9d3b8770f2
After debianutils upgrades to 4.11.1 in [1], there is no 4.11.1 source in the old debian snapshot. Update the snapshot version to fix the gap. [1] https://git.openembedded.org/openembedded-core/commit/?id=0c492a0768cd15ff40db35f459853e69c55f8cc6 (From OE-Core rev: a58f69f854c28d61a8c74b8af75b80b8695f6198) Signed-off-by: Mingli Yu <mingli.yu@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
55 lines
1.9 KiB
BlitzBasic
55 lines
1.9 KiB
BlitzBasic
SUMMARY = "Miscellaneous utilities specific to Debian"
|
|
SECTION = "base"
|
|
LICENSE = "GPLv2 & SMAIL_GPL"
|
|
LIC_FILES_CHKSUM = "file://debian/copyright;md5=9b912cd0cc654134c0ef3424a0705b94"
|
|
|
|
SRC_URI = "http://snapshot.debian.org/archive/debian/20200929T025235Z/pool/main/d/${BPN}/${BPN}_${PV}.tar.xz"
|
|
# the package is taken from snapshots.debian.org; that source is static and goes stale
|
|
# so we check the latest upstream from a directory that does get updated
|
|
UPSTREAM_CHECK_URI = "${DEBIAN_MIRROR}/main/d/${BPN}/"
|
|
|
|
SRC_URI[sha256sum] = "8be869f19c55c18d53d9f0414b68bb966a068b2154e9fbbfc6193827d6af983c"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
do_configure_prepend() {
|
|
sed -i -e 's:tempfile.1 which.1:which.1:g' ${S}/Makefile.am
|
|
}
|
|
|
|
do_install_append() {
|
|
if [ "${base_bindir}" != "${bindir}" ]; then
|
|
# Debian places some utils into ${base_bindir} as does busybox
|
|
install -d ${D}${base_bindir}
|
|
for app in run-parts tempfile; do
|
|
mv ${D}${bindir}/$app ${D}${base_bindir}/$app
|
|
done
|
|
fi
|
|
}
|
|
|
|
# Note that we package the update-alternatives name.
|
|
#
|
|
PACKAGES =+ "${PN}-run-parts"
|
|
FILES_${PN}-run-parts = "${base_bindir}/run-parts.debianutils"
|
|
|
|
RDEPENDS_${PN} += "${PN}-run-parts"
|
|
RDEPENDS_${PN}_class-native = ""
|
|
|
|
ALTERNATIVE_PRIORITY = "30"
|
|
ALTERNATIVE_${PN} = "add-shell installkernel remove-shell savelog tempfile which"
|
|
|
|
ALTERNATIVE_PRIORITY_${PN}-run-parts = "60"
|
|
ALTERNATIVE_${PN}-run-parts = "run-parts"
|
|
|
|
ALTERNATIVE_${PN}-doc = "which.1"
|
|
ALTERNATIVE_LINK_NAME[which.1] = "${mandir}/man1/which.1"
|
|
|
|
ALTERNATIVE_LINK_NAME[add-shell] = "${sbindir}/add-shell"
|
|
ALTERNATIVE_LINK_NAME[installkernel] = "${sbindir}/installkernel"
|
|
ALTERNATIVE_LINK_NAME[remove-shell] = "${sbindir}/remove-shell"
|
|
ALTERNATIVE_LINK_NAME[run-parts] = "${base_bindir}/run-parts"
|
|
ALTERNATIVE_LINK_NAME[savelog] = "${bindir}/savelog"
|
|
ALTERNATIVE_LINK_NAME[tempfile] = "${base_bindir}/tempfile"
|
|
ALTERNATIVE_LINK_NAME[which] = "${bindir}/which"
|
|
|
|
BBCLASSEXTEND = "native"
|