mirror of
https://git.yoctoproject.org/poky
synced 2026-02-11 19:23:03 +01:00
9c1efb65c9
Previously the check for some recipes relied on sourceforge redirecting from downloads.sourceforge.net (SRC_URI is set to that) into the actual project page. Sourceforge does this for interactive browsers, but not for wget. With the check no longer mimicking a browser, and being truthful about coming from wget we need to explicitly fetch the project page in all cases, which is what this commit does. (many recipes already set this explicitly and don't need to be tweaked) (From OE-Core rev: 4c21ce6e34f6ce8fbf4db7bc2fd017c8f7a811b4) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.5 KiB
PHP
41 lines
1.5 KiB
PHP
SUMMARY = "A daemon for delivering ACPI events"
|
|
DESCRIPTION = "ACPID is a completely flexible, totally extensible daemon for \
|
|
delivering ACPI events. It listens on netlink interface (or on the \
|
|
deprecated file /proc/acpi/event), and when an event occurs, executes programs \
|
|
to handle the event. The programs it executes are configured through a set of \
|
|
configuration files, which can be dropped into place by packages or by the \
|
|
admin."
|
|
HOMEPAGE = "http://sourceforge.net/projects/acpid2"
|
|
BUGTRACKER = "http://sourceforge.net/p/acpid2/tickets/?source=navbar"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
|
|
SOURCEFORGE_PROJECT = "acpid2"
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/${SOURCEFORGE_PROJECT}/acpid-${PV}.tar.xz \
|
|
file://init \
|
|
file://acpid.service \
|
|
file://0001-Replace-stat64-with-stat.patch \
|
|
"
|
|
|
|
CVE_PRODUCT = "acpid2"
|
|
|
|
inherit autotools update-rc.d systemd sourceforge-releases
|
|
|
|
INITSCRIPT_NAME = "acpid"
|
|
INITSCRIPT_PARAMS = "defaults"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "acpid.service"
|
|
|
|
do_install:append () {
|
|
install -d ${D}${sysconfdir}/init.d
|
|
sed -e 's,/usr/sbin,${sbindir},g' ${UNPACKDIR}/init > ${D}${sysconfdir}/init.d/acpid
|
|
chmod 755 ${D}${sysconfdir}/init.d/acpid
|
|
|
|
install -d ${D}${sysconfdir}/acpi
|
|
install -d ${D}${sysconfdir}/acpi/events
|
|
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${UNPACKDIR}/acpid.service ${D}${systemd_system_unitdir}
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' ${D}${systemd_system_unitdir}/acpid.service
|
|
}
|