mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 01:36:38 +01:00
3cd2c2fb08
0001-scripts-dtc-clean-up-yamltree-from-dtc.patch removed since it's included in 2025.04.0 (From OE-Core rev: fe299607a9ba8dbdd3d45c12e75c423cc8f3971e) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
1.1 KiB
BlitzBasic
56 lines
1.1 KiB
BlitzBasic
SUMMARY = "barebox bootloader tools"
|
|
|
|
require barebox-common.inc
|
|
|
|
LICENSE = "GPL-2.0-only"
|
|
|
|
DEPENDS = "bison-native flex-native libusb1"
|
|
|
|
S = "${WORKDIR}/barebox-${PV}"
|
|
B = "${WORKDIR}/build"
|
|
|
|
inherit pkgconfig
|
|
|
|
EXTRA_OEMAKE = " \
|
|
ARCH=sandbox \
|
|
CROSS_COMPILE=${TARGET_PREFIX} -C ${S} O=${B} \
|
|
CROSS_PKG_CONFIG=pkg-config \
|
|
CC='${CC}' \
|
|
LD='${LD}' \
|
|
"
|
|
|
|
do_compile:class-target () {
|
|
export userccflags="${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
|
|
export userldflags="${TARGET_LDFLAGS}${TOOLCHAIN_OPTIONS}"
|
|
oe_runmake targettools_defconfig
|
|
oe_runmake scripts
|
|
}
|
|
|
|
do_compile:class-native () {
|
|
oe_runmake hosttools_defconfig
|
|
oe_runmake scripts
|
|
}
|
|
|
|
BAREBOX_TOOLS = " \
|
|
bareboxenv \
|
|
bareboxcrc32 \
|
|
kernel-install \
|
|
bareboximd \
|
|
omap3-usb-loader \
|
|
omap4_usbboot \
|
|
imx/imx-usb-loader \
|
|
"
|
|
|
|
BAREBOX_TOOLS_SUFFIX = ""
|
|
BAREBOX_TOOLS_SUFFIX:class-target = "-target"
|
|
|
|
do_install () {
|
|
install -d ${D}${bindir}
|
|
|
|
for tool in ${BAREBOX_TOOLS}; do
|
|
install -m 0755 scripts/${tool}${BAREBOX_TOOLS_SUFFIX} ${D}${bindir}/${tool##*/}
|
|
done
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|