mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 18:02:12 +01:00
b46037db40
License-Update: Updated copyright years and contibutors [1]
Brings following changes
* b7bfe0b Update documentation for 1.1 release
* f0de9c6 CHANGELOG: Add pthread section
* 36f21a6 pthread: add pthread_mutexattr_[get|set]kind_np
* f23fb58 stdio: Hook fopen(3) to intercept /proc/self/exe
* 158f2b5 Update CHANGELOG for 1.1
* 4a4c840 fix path-searching for execvp
* 9dbbddc sysctl: Add __getauxval alias
* fbdd06c misc: add __libc_single_threaded
* f727ab7 locale: also override __newlocale/__duplocale
* 244110e random_r: fix null dereference when passed uninitialized buf
[1] b7bfe0b08c (0398ccd0f49298b10a3d76a47800d2ebecd49859)
(From OE-Core rev: 6f123655c71992d75746e662a6b757de4a57cce7)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
61 lines
1.6 KiB
BlitzBasic
61 lines
1.6 KiB
BlitzBasic
# Copyright (C) 2021 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "A library which provides glibc-compatible APIs for use on musl libc systems"
|
|
HOMEPAGE = "https://git.adelielinux.org/adelie/gcompat"
|
|
|
|
LICENSE = "NCSA"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=802b1aed7330d90086be4de63a3188e3"
|
|
|
|
SRC_URI = "git://git.adelielinux.org/adelie/gcompat.git;protocol=https;branch=current \
|
|
file://0001-Add-fcntl64-wrapper.patch \
|
|
"
|
|
SRC_URI:append:powerpc = "\
|
|
file://0001-make-Static-PIE-does-not-work-on-musl-ppc.patch \
|
|
"
|
|
PV = "1.1.0"
|
|
SRCREV = "b7bfe0b08c52fdc72e0c1d9d4dcb2129f1642bd6"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit pkgconfig linuxloader siteinfo
|
|
|
|
DEPENDS += "musl-obstack"
|
|
|
|
GLIBC_LDSO = "${@get_glibc_loader(d)}"
|
|
MUSL_LDSO = "${@get_musl_loader(d)}"
|
|
|
|
EXTRA_OEMAKE = "LINKER_PATH=${MUSL_LDSO} \
|
|
LOADER_NAME=`basename ${GLIBC_LDSO}` \
|
|
"
|
|
|
|
do_configure () {
|
|
:
|
|
}
|
|
|
|
do_compile () {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install () {
|
|
oe_runmake install 'DESTDIR=${D}${root_prefix}'
|
|
if [ "${SITEINFO_BITS}" = "64" ]; then
|
|
install -d ${D}${nonarch_base_libdir}${SITEINFO_BITS}
|
|
ln -rs ${D}${GLIBC_LDSO} ${D}${nonarch_base_libdir}${SITEINFO_BITS}/`basename ${GLIBC_LDSO}`
|
|
fi
|
|
install -d ${D}${libdir}
|
|
ln -sf ${base_libdir}/libgcompat.so.0 ${D}${libdir}/libgcompat.so
|
|
}
|
|
|
|
FILES:${PN} += "${nonarch_base_libdir}${SITEINFO_BITS}"
|
|
|
|
INSANE_SKIP:${PN} = "libdir"
|
|
|
|
RPROVIDES:${PN} += "musl-glibc-compat"
|
|
#
|
|
# We will skip parsing for non-musl systems
|
|
#
|
|
COMPATIBLE_HOST = ".*-musl.*"
|
|
|
|
UPSTREAM_CHECK_COMMITS = "1"
|