mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 08:18:43 +01:00
15e88b968e
libbfd is enabled and it invokes libtool relink step to get rid of rpaths during install step. libtool 2.4 patches rightly prepend lt_sysroot to target libdir which relink step would use, such a patch is also upstreamed into libtool [1] However, when we do not specify --with-libtool-sysroot, lt_sysoot prefix turns out to be empty and relink step adds -L/usr/lib to linker command line. it cause all sort of problems e.g. when the build host has zlib installed then libbfd tries to link with /usr/lib/libz.so instead of the one in target sysroot, fortunately OE linker reports host path contamination and fails the build. Second problem seen when building target binutils on musl, it links with libc.so correctly but libtool relink step resolves libc.so in /usr/lib due to this path and expands it into libc.so.6 and ld-linux-x86-64.so.2 ( glibc host's libc.so is a linker stub ) in DT_NEEDED ELF section which does not work with musl linker and build QA detects this anamoly as well. ERROR: binutils-2.44-r0 do_package_qa: QA Issue: /usr/lib/libbfd-2.44.so contained in package libbfd requires libc.so.6(GLIBC_2.34)(64bit), but no providers found in RDEPENDS:libbfd? [file-rdeps] This inconsistency may cause produced binaries mistakenly linked against libraries from the host distro. Add libtool sysroot to point libtool to correct sysroot location during build. [1] https://git.savannah.gnu.org/cgit/libtool.git/commit/?id=3221f9f0fb98d5740ab5d0e8db6a731302520644 (From OE-Core rev: 89e984bd7edb9a2013b65d0215fd6af9aadd59e8) Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
82 lines
3.3 KiB
BlitzBasic
82 lines
3.3 KiB
BlitzBasic
require binutils.inc
|
|
require binutils-${PV}.inc
|
|
|
|
# perl-native for pod2man for man page generation
|
|
DEPENDS += "zlib perl-native"
|
|
|
|
EXTRA_OECONF += "--with-sysroot=/ \
|
|
--with-libtool-sysroot=${STAGING_DIR_HOST} \
|
|
--enable-install-libbfd \
|
|
--enable-install-libiberty \
|
|
--enable-shared \
|
|
--with-system-zlib \
|
|
"
|
|
|
|
EXTRA_OEMAKE:append:libc-musl = "\
|
|
gt_cv_func_gnugettext1_libc=yes \
|
|
gt_cv_func_gnugettext2_libc=yes \
|
|
"
|
|
# libcollector/collector.c:547:15: error: no member named '__fprintf_chk' in 'struct CollectorUtilFuncs'
|
|
EXTRA_OECONF:append:toolchain-clang = " --disable-gprofng"
|
|
# | ../../../gprofng/libcollector/../src/collector_module.h:78:13: error: duplicate member 'pwrite'
|
|
# | ../../../gprofng/libcollector/dispatcher.c:578:8: error: 'struct sigevent' has no member named '_sigev_un'
|
|
EXTRA_OECONF:append:libc-musl = " --disable-gprofng"
|
|
|
|
EXTRA_OECONF:class-native = "--enable-targets=all \
|
|
--enable-64-bit-bfd \
|
|
--enable-install-libiberty \
|
|
--enable-install-libbfd \
|
|
--disable-gdb \
|
|
--disable-gdbserver \
|
|
--disable-libdecnumber \
|
|
--disable-readline \
|
|
--disable-sim \
|
|
--disable-werror"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'debuginfod', d)}"
|
|
PACKAGECONFIG[debuginfod] = "--with-debuginfod, --without-debuginfod, elfutils"
|
|
|
|
do_install:class-native () {
|
|
autotools_do_install
|
|
|
|
# Install the libiberty header
|
|
install -d ${D}${includedir}
|
|
install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
|
|
install -m 644 ${S}/include/libiberty.h ${D}${includedir}
|
|
|
|
# We only want libiberty, libbfd and libopcodes
|
|
rm -rf ${D}${bindir}
|
|
rm -rf ${D}${prefix}/${TARGET_SYS}
|
|
rm -rf ${D}${prefix}/lib/ldscripts
|
|
rm -rf ${D}${prefix}/share/info
|
|
rm -rf ${D}${prefix}/share/locale
|
|
rm -rf ${D}${prefix}/share/man
|
|
rmdir ${D}${prefix}/share || :
|
|
rmdir ${D}/${libdir}/gcc-lib || :
|
|
rmdir ${D}/${libdir}64/gcc-lib || :
|
|
rmdir ${D}/${libdir} || :
|
|
rmdir ${D}/${libdir}64 || :
|
|
}
|
|
|
|
# libctf races with libbfd
|
|
PARALLEL_MAKEINST:class-target = ""
|
|
PARALLEL_MAKEINST:class-nativesdk = ""
|
|
|
|
# Split out libbfd-*.so and libopcodes-*.so so including perf doesn't include
|
|
# extra stuff
|
|
PACKAGE_BEFORE_PN += "libbfd libopcodes gprofng"
|
|
FILES:libbfd = "${libdir}/libbfd-*.so.* ${libdir}/libbfd-*.so"
|
|
FILES:libopcodes = "${libdir}/libopcodes-*.so.* ${libdir}/libopcodes-*.so"
|
|
FILES:gprofng = "${sysconfdir}/gprofng.rc ${libdir}/gprofng/libgp-*.so ${libdir}/gprofng/libgprofng.so.* ${bindir}/gprofng-* ${bindir}/gprofng"
|
|
FILES:${PN}-dev += "${libdir}/libgprofng.so ${libdir}/libsframe.so"
|
|
SRC_URI:append:class-nativesdk = " file://0003-binutils-nativesdk-Search-for-alternative-ld.so.conf.patch "
|
|
|
|
USE_ALTERNATIVES_FOR:class-nativesdk = ""
|
|
FILES:${PN}:append:class-nativesdk = " ${bindir}"
|
|
RDEPENDS:gprofng:class-nativesdk = " nativesdk-perl-module-bignum \
|
|
nativesdk-perl-module-bigint \
|
|
nativesdk-perl-module-math-bigint \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|