mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
79030cd4c4
This can ensure that meta-clang does not carry them and can rely on core layer while mesa can use them too. Omit time stamps in openmp from generated files to improve reproducibility fix the issue that: | file /usr/include/llvm/Config/llvm-config.h conflicts between attempted installs of lib32-llvm-dev-20.1.2-r0.core2_32 and llvm-dev-20.1.2-r0.core2_64 (From OE-Core rev: d77e398095228b34851762858a76640e3c2cb0ab) Signed-off-by: Dmitry Baryshkov <dmitry.baryshkov@oss.qualcomm.com> Signed-off-by: Khem Raj <raj.khem@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
40 lines
1.5 KiB
BlitzBasic
40 lines
1.5 KiB
BlitzBasic
# Copyright (C) 2014 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "Cross compiler wrappers for LLVM based C/C++ compiler"
|
|
HOMEPAGE = "http://clang.llvm.org/"
|
|
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/Apache-2.0-with-LLVM-exception;md5=0bcd48c3bdfef0c9d9fd17726e4b7dab"
|
|
SECTION = "devel"
|
|
|
|
PN = "clang-cross-${TARGET_ARCH}"
|
|
|
|
require common-clang.inc
|
|
require common-source.inc
|
|
inherit cross
|
|
DEPENDS += "clang-native virtual/cross-binutils"
|
|
|
|
#INHIBIT_PACKAGE_STRIP = "1"
|
|
INHIBIT_SYSROOT_STRIP = "1"
|
|
do_install() {
|
|
install -d ${D}${bindir}
|
|
for tool in clang-tidy lld ld.lld llvm-profdata \
|
|
llvm-nm llvm-ar llvm-as llvm-ranlib llvm-strip llvm-objcopy llvm-objdump llvm-readelf \
|
|
llvm-addr2line llvm-dwp llvm-size llvm-strings llvm-cov
|
|
do
|
|
ln -sf ../$tool ${D}${bindir}/${TARGET_PREFIX}$tool
|
|
done
|
|
install -m 0755 ${STAGING_BINDIR_NATIVE}/clang ${D}${bindir}/${TARGET_PREFIX}clang
|
|
install -m 0755 ${STAGING_BINDIR_NATIVE}/clang ${D}${bindir}/${TARGET_PREFIX}clang++
|
|
}
|
|
SSTATE_SCAN_FILES += "*-clang *-clang++ *-llvm-profdata *-lld *-ld.lld \
|
|
*-llvm-nm *-llvm-ar *-llvm-as *-llvm-ranlib *-llvm-strip \
|
|
*-llvm-objcopy *-llvm-objdump *-llvm-readelf *-llvm-addr2line \
|
|
*-llvm-dwp *-llvm-size *-llvm-strings *-llvm-cov"
|
|
|
|
SYSROOT_PREPROCESS_FUNCS += "clangcross_sysroot_preprocess"
|
|
|
|
clangcross_sysroot_preprocess () {
|
|
sysroot_stage_dir ${D}${bindir} ${SYSROOT_DESTDIR}${bindir}
|
|
}
|
|
PACKAGES = ""
|