mirror of
https://git.yoctoproject.org/poky
synced 2026-02-05 16:28:43 +01:00
ea00dbbcf3
-ffile-prefix map is more comprehensive when it comes to reproducible builds and its superset of all prefix-mapping options in compilers This makes is cleaner and workable across gcc and clang, clang does not support -fcanon-prefix-map and it has to be explicitly omitted when using clang. There are lambdas generated in templates by clang which still get the absolute paths despite -fdebug-prefix-map, this helps with that as well. nasm is an outlier and we have fixed it by adding -fdebug-prefix-map option luckily we do not pass DEBUG_PREFIX_MAP to nasm, in all recipes which use nasm either pass -fdebug-prefix-map explicitly to nasm or they rewrite it to use nasm flags syntax. We have discussed this in past [1] [1] https://patchwork.yoctoproject.org/project/oe-core/patch/20230428032030.2047920-1-raj.khem@gmail.com/#10281 (From OE-Core rev: ff73fa7ef7666a6dbe34f15515bc3ab6e574c5b0) Signed-off-by: Khem Raj <raj.khem@gmail.com> Cc: Jacob Kroon <jacob.kroon@gmail.com> Cc: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
90 lines
2.8 KiB
PHP
90 lines
2.8 KiB
PHP
require gcc-configure-common.inc
|
|
|
|
EXTRA_OECONF_PATHS = "\
|
|
--with-sysroot=/not/exist \
|
|
--with-build-sysroot=${STAGING_DIR_TARGET} \
|
|
"
|
|
|
|
# An arm hard float target like raspberrypi4 won't build
|
|
# as CFLAGS don't make it to the fortran compiler otherwise
|
|
# (the configure script sets FC to $GFORTRAN unconditionally)
|
|
export GFORTRAN = "${FC} -ffile-prefix-map=${S}=${TARGET_DBGSRC_DIR} -ffile-prefix-map=${B}=${TARGET_DBGSRC_DIR} -gno-record-gcc-switches"
|
|
|
|
do_configure () {
|
|
for target in libbacktrace libgfortran
|
|
do
|
|
rm -rf ${B}/${TARGET_SYS}/$target/
|
|
mkdir -p ${B}/${TARGET_SYS}/$target/
|
|
cd ${B}/${TARGET_SYS}/$target/
|
|
chmod a+x ${S}/$target/configure
|
|
relpath=${@os.path.relpath("${S}", "${B}/${TARGET_SYS}")}
|
|
../$relpath/$target/configure ${CONFIGUREOPTS} ${EXTRA_OECONF}
|
|
# Easiest way to stop bad RPATHs getting into the library since we have a
|
|
# broken libtool here
|
|
sed -i -e 's/hardcode_into_libs=yes/hardcode_into_libs=no/' ${B}/${TARGET_SYS}/$target/libtool
|
|
done
|
|
}
|
|
EXTRACONFFUNCS += "extract_stashed_builddir"
|
|
do_configure[depends] += "${COMPILERDEP}"
|
|
|
|
do_compile () {
|
|
for target in libbacktrace libgfortran
|
|
do
|
|
cd ${B}/${TARGET_SYS}/$target/
|
|
oe_runmake MULTIBUILDTOP=${B}/${TARGET_SYS}/$target/
|
|
done
|
|
}
|
|
|
|
do_install () {
|
|
cd ${B}/${TARGET_SYS}/libgfortran/
|
|
oe_runmake 'DESTDIR=${D}' MULTIBUILDTOP=${B}/${TARGET_SYS}/libgfortran/ install
|
|
if [ -d ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude ]; then
|
|
rmdir --ignore-fail-on-non-empty -p ${D}${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude
|
|
fi
|
|
if [ -d ${D}${infodir} ]; then
|
|
rmdir --ignore-fail-on-non-empty -p ${D}${infodir}
|
|
fi
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
# avoid virtual/libc
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
DEPENDS = "virtual/cross-cc virtual/compilerlibs"
|
|
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|
|
PACKAGES = "\
|
|
${PN}-dbg \
|
|
libgfortran \
|
|
libgfortran-dev \
|
|
libgfortran-staticdev \
|
|
"
|
|
|
|
LICENSE:${PN} = "GPL-3.0-with-GCC-exception"
|
|
LICENSE:${PN}-dev = "GPL-3.0-with-GCC-exception"
|
|
LICENSE:${PN}-dbg = "GPL-3.0-with-GCC-exception"
|
|
|
|
FILES:${PN} = "${libdir}/libgfortran.so.*"
|
|
FILES:${PN}-dev = "\
|
|
${libdir}/libgfortran*.so \
|
|
${libdir}/libgfortran.spec \
|
|
${libdir}/libgfortran.la \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/libgfortranbegin.* \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/libcaf_single* \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/finclude/ \
|
|
${libdir}/gcc/${TARGET_SYS}/${BINV}/include/ \
|
|
"
|
|
FILES:${PN}-staticdev = "${libdir}/libgfortran.a"
|
|
|
|
INSANE_SKIP:${MLPREFIX}libgfortran-dev = "staticdev"
|
|
|
|
do_package_write_ipk[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_deb[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
do_package_write_rpm[depends] += "virtual/${MLPREFIX}libc:do_packagedata"
|
|
|
|
python __anonymous () {
|
|
f = d.getVar("FORTRAN")
|
|
if "fortran" not in f:
|
|
raise bb.parse.SkipRecipe("libgfortran needs fortran support to be enabled in the compiler")
|
|
}
|