mirror of
https://git.yoctoproject.org/poky
synced 2026-02-28 20:39:39 +01:00
bb6ddc3691
This is the result of automated script conversion: scripts/contrib/convert-overrides.py <oe-core directory> converting the metadata to use ":" as the override character instead of "_". (From OE-Core rev: 42344347be29f0997cc2f7636d9603b1fe1875ae) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
44 lines
1.4 KiB
BlitzBasic
44 lines
1.4 KiB
BlitzBasic
SUMMARY = "Keyrings for verifying opkg packages and feeds"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
|
|
|
|
# Distro-specific keys can be added to this package in two ways:
|
|
#
|
|
# 1) In a .bbappend, add .gpg and/or .asc files to SRC_URI and install them to
|
|
# ${D}${datadir}/opkg/keyrings/ in a do_install:append function. These
|
|
# files should not be named 'key-$name.gpg' to ensure they don't conflict
|
|
# with keys exported as per (2).
|
|
#
|
|
# 2) In a .bbappend, distro config or local.conf, override the variable
|
|
# OPKG_KEYRING_KEYS to contain a space-separated list of key names. For
|
|
# each name, 'gpg --export $name' will be ran to export the public key to a
|
|
# file named 'key-$name.gpg'. The public key must therefore be in the gpg
|
|
# keyrings on the build machine.
|
|
|
|
OPKG_KEYRING_KEYS ?= ""
|
|
|
|
do_compile() {
|
|
for name in ${OPKG_KEYRING_KEYS}; do
|
|
gpg --export ${name} > ${B}/key-${name}.gpg
|
|
done
|
|
}
|
|
|
|
do_install () {
|
|
install -d ${D}${datadir}/opkg/keyrings/
|
|
for name in ${OPKG_KEYRING_KEYS}; do
|
|
install -m 0644 ${B}/key-${name}.gpg ${D}${datadir}/opkg/keyrings/
|
|
done
|
|
}
|
|
|
|
FILES:${PN} = "${datadir}/opkg/keyrings"
|
|
|
|
# We need 'opkg-key' to run the postinst script
|
|
RDEPENDS:${PN} = "opkg"
|
|
|
|
pkg_postinst_ontarget:${PN} () {
|
|
if test -x ${bindir}/opkg-key
|
|
then
|
|
${bindir}/opkg-key populate
|
|
fi
|
|
}
|