mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 01:36:38 +01:00
3f4fbbdbea
Release highlights: https://github.com/strace/strace/releases/tag/v6.12 Drop patch merged upstream: 0001-sched_attr-Define-conditionally-on-SCHED_ATTR_SIZE_V.patch 3b6f69aa2 sched_attr: Define conditionally on SCHED_ATTR_SIZE_VER1 qemux86-64 ptest results: glibc musl: TOTAL: 1393 1393 PASS: 1066 1059 SKIP: 327 330 XFAIL: 0 0 FAIL: 0 4 XPASS: 0 0 ERROR: 0 0 The skipped tests are mostly SELinux. The musl tests that fail, currently for unknown reasons, are: pread64-pwrite64.gen preadv-pwritev.gen pwritev.gen uio At least for pread64-pwrite6 the pwrite(64) syscalls are not traced and that makes the test fail. (From OE-Core rev: 07d4e9312781f5a865cbdd088d5e3485e8c1bffc) Signed-off-by: Randy MacLeod <Randy.MacLeod@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
2.3 KiB
BlitzBasic
56 lines
2.3 KiB
BlitzBasic
SUMMARY = "System call tracing tool"
|
|
HOMEPAGE = "http://strace.io"
|
|
DESCRIPTION = "strace is a diagnostic, debugging and instructional userspace utility for Linux. It is used to monitor and tamper with interactions between processes and the Linux kernel, which include system calls, signal deliveries, and changes of process state."
|
|
SECTION = "console/utils"
|
|
LICENSE = "LGPL-2.1-or-later & GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2433d82e1432a76dc3eadd9002bfe304"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/strace-${PV}.tar.xz \
|
|
file://update-gawk-paths.patch \
|
|
file://Makefile-ptest.patch \
|
|
file://run-ptest \
|
|
file://ptest-spacesave.patch \
|
|
file://0001-strace-fix-reproducibilty-issues.patch \
|
|
file://skip-load.patch \
|
|
file://0001-configure-Use-autoconf-macro-to-detect-largefile-sup.patch \
|
|
file://0002-tests-Replace-off64_t-with-off_t.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "c47da93be45b6055f4dc741d7f20efaf50ca10160a5b100c109b294fd9c0bdfe"
|
|
|
|
|
|
inherit autotools github-releases ptest
|
|
|
|
# Not yet ported to rv32
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
# bluez is not enabled by default due to build dependency creep in smaller builds
|
|
# like core-image-minimal leading to significantly more tasks being executed
|
|
PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
|
|
PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
|
|
|
|
EXTRA_OECONF += "--enable-mpers=no --disable-gcc-Werror"
|
|
|
|
CFLAGS:append:libc-musl = " -Dsigcontext_struct=sigcontext"
|
|
|
|
TESTDIR = "tests"
|
|
PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${TESTDIR} buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest() {
|
|
oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
|
|
mkdir -p ${D}${PTEST_PATH}/build-aux
|
|
mkdir -p ${D}${PTEST_PATH}/src
|
|
install -m 755 ${S}/build-aux/test-driver ${D}${PTEST_PATH}/build-aux/
|
|
install -m 644 ${B}/src/config.h ${D}${PTEST_PATH}/src/
|
|
sed -e '/^src/s/strace.*[0-9]/ptest/' \
|
|
-e "/^TEST_LOG_DRIVER =/s|(top_srcdir)|(top_builddir)|" \
|
|
-i ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
|
|
}
|
|
|
|
RDEPENDS:${PN}-ptest += "make coreutils grep gawk sed locale-base-en-us"
|
|
|
|
BBCLASSEXTEND = "native"
|