mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 09:16:36 +01:00
0b7d336937
Upstream has an autogen.sh which constructs a hand-written aclocal.m4 and manually copies libtool into place. Instead of working around the bad interaction between these expectations and our autotools class we can just disable the execution of aclocal in autoreconf and copy files as autogen.sh does. (From OE-Core rev: ce0865e9a79b1603a2553392f2cd3b6394239153) Signed-off-by: Ross Burton <ross.burton@arm.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
3.8 KiB
BlitzBasic
63 lines
3.8 KiB
BlitzBasic
SUMMARY = "Subversion (svn) version control system client"
|
|
HOMEPAGE = "http://subversion.apache.org"
|
|
DESCRIPTION = "Subversion is an open source version control system."
|
|
SECTION = "console/network"
|
|
LICENSE = "Apache-2.0 & MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=6487ae7094d359fa90fb9c4096e52e2b"
|
|
|
|
DEPENDS = "apr-util serf sqlite3 file lz4 expat"
|
|
DEPENDS:append:class-native = " file-replacement-native"
|
|
|
|
SRC_URI = "${APACHE_MIRROR}/${BPN}/${BPN}-${PV}.tar.bz2 \
|
|
file://serfmacro.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "e78a29e7766b8b7b354497d08f71a55641abc53675ce1875584781aae35644a1"
|
|
|
|
inherit autotools pkgconfig gettext python3native
|
|
|
|
CVE_PRODUCT = "apache:subversion"
|
|
|
|
PACKAGECONFIG ?= ""
|
|
|
|
PACKAGECONFIG[boost] = "--with-boost=${RECIPE_SYSROOT}${exec_prefix},--without-boost,boost"
|
|
PACKAGECONFIG[sasl] = "--with-sasl,--without-sasl,cyrus-sasl"
|
|
PACKAGECONFIG[gnome-keyring] = "--with-gnome-keyring,--without-gnome-keyring,glib-2.0 gnome-keyring"
|
|
|
|
EXTRA_OECONF = " \
|
|
--with-apr=${STAGING_BINDIR_CROSS} \
|
|
--with-apr-util=${STAGING_BINDIR_CROSS} \
|
|
--without-apxs \
|
|
--without-berkeley-db \
|
|
--without-swig \
|
|
--disable-keychain \
|
|
--with-utf8proc=internal \
|
|
ac_cv_path_RUBY=none \
|
|
"
|
|
|
|
# Upstream puts the .pc in $datadir
|
|
EXTRA_OEMAKE += "pkgconfig_dir=${libdir}/pkgconfig"
|
|
|
|
CPPFLAGS += "-P"
|
|
BUILD_CPPFLAGS += "-P"
|
|
|
|
EXTRA_AUTORECONF += "--exclude=aclocal"
|
|
|
|
do_configure:prepend () {
|
|
# autogen.sh manually puts things in the right place, and libtoolize doesn't
|
|
# work as they don't use aclocal
|
|
cp -f ${S}/aclocal.m4.in ${S}/aclocal.m4
|
|
cp -f ${STAGING_DATADIR}/aclocal/libtool.m4 ${STAGING_DATADIR}/aclocal/lt*.m4 ${S}/build/
|
|
}
|
|
|
|
#| x86_64-linux-libtool: install: warning: `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/work/x86_64-linux/subversion-native/1.8.9-r0/build/subversion/libsvn_ra_local/libsvn_ra_local-1.la' has not been installed in `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/sysroots/x86_64-linux/usr/lib'| x86_64-linux-libtool: install: warning: `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/work/x86_64-linux/subversion-native/1.8.9-r0/build/subversion/libsvn_repos/libsvn_repos-1.la' has not been installed in `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/sysroots/x86_64-linux/usr/lib'| /usr/bin/ld: cannot find -lsvn_delta-1| collect2: ld returned 1 exit status| x86_64-linux-libtool: install: warning: `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/work/x86_64-linux/subversion-native/1.8.9-r0/build/subversion/libsvn_ra_svn/libsvn_ra_svn-1.la' has not been installed in `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/sysroots/x86_64-linux/usr/lib'| x86_64-linux-libtool: install: warning: `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/work/x86_64-linux/subversion-native/1.8.9-r0/build/subversion/libsvn_ra_serf/libsvn_ra_serf-1.la' has not been installed in `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/sysroots/x86_64-linux/usr/lib'
|
|
#| x86_64-linux-libtool: install: error: relink `libsvn_ra_serf-1.la' with the above command before installing it
|
|
#| x86_64-linux-libtool: install: warning: `../../subversion/libsvn_repos/libsvn_repos-1.la' has not been installed in `/home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/sysroots/x86_64-linux/usr/lib'
|
|
#| /home/pokybuild/yocto-autobuilder/yocto-worker/nightly-qa-logrotate/build/build/tmp/work/x86_64-linux/subversion-native/1.8.9-r0/subversion-1.8.9/build-outputs.mk:1090: recipe for target 'install-serf-lib' failed
|
|
#| make: *** [install-serf-lib] Error 1
|
|
PARALLEL_MAKEINST = ""
|
|
|
|
RDEPENDS:${PN} = "serf"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|