mirror of
https://git.yoctoproject.org/poky
synced 2026-02-09 10:13:03 +01:00
ae398ec14e
- this update is required to work with gobject-introspection >= 1.83.2 Vala 0.56.18 ============ * Various improvements and bug fixes: - vala: Don't allow inheritance of compact class from non-compact class - vala, libvaladoc: Fix color support detection in log reporting - girparser: Handle `doc:format` element in root:repository [#1586] - codegen: Use correct ctype for result variable in methods in more cases - codegen: Fix conditional expression with only one void side - valadoc: Sync gir argument handling from valacompiler.vala - Update links to GNOME Wiki project and refer to new Vala websites - Add CI for tarball release service * Bindings: - gio-2.0: Improve the {Input,Output}Message bindings - glib-2.0: Fix the binding of `get_console_charset` - glib-2.0: Add missing CCode.array_null_terminated attributes to IConv.iconv() - glib-2.0: Make FileStream.*printf() return int [#1547] - glib-2.0: Update RegexMatchFlags and RegexCompileFlags's binding to 2.74 - glib-2.0: Add Regex.escape_nul in GLib - gnu: add binding for 'relocate' APIs - gobject-2.0: Add TypeFlags missing values - gstreamer-1.0: Skip ParamSpecArray and ParamSpecFraction - libusb-1.0: Fix the LibUSB.TransferCb declaration - libusb-1.0: Fix the LibUSB.HotPlugCb declaration - sdl2: Fix CCode.destroy_function of SDL.RWops and usage of SDL.RWops.from_file() [#1550] - sdl2: Fix missing integer type for JoystickID [#1563] (From OE-Core rev: 6aa3e8e7b701590097ecefc3cf9a193423c5a5ea) Signed-off-by: Markus Volk <f_l_k@t-online.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
74 lines
2.9 KiB
BlitzBasic
74 lines
2.9 KiB
BlitzBasic
SUMMARY = "C#-like programming language for easing GObject programming"
|
|
HOMEPAGE = "http://vala-project.org"
|
|
DESCRIPTION = "Vala is a C#-like language dedicated to ease GObject programming. \
|
|
Vala compiles to plain C and has no runtime environment nor penalities whatsoever."
|
|
SECTION = "devel"
|
|
DEPENDS = "bison-native flex-native glib-2.0 gobject-introspection"
|
|
|
|
# Appending libxslt-native to dependencies has an effect
|
|
# of rebuilding the manual, which is very slow. Let's do this
|
|
# only when api-documentation distro feature is enabled.
|
|
DEPENDS:append:class-target = " ${@bb.utils.contains('DISTRO_FEATURES', 'api-documentation', 'libxslt-native', '', d)}"
|
|
|
|
# vala-native contains a native version of vapigen, which we use instead of the target one
|
|
DEPENDS:append:class-target = " vala-native"
|
|
BBCLASSEXTEND = "native"
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=fbc093901857fcd118f065f900982c24"
|
|
|
|
SHRT_VER = "${@d.getVar('PV').split('.')[0]}.${@d.getVar('PV').split('.')[1]}"
|
|
|
|
SRC_URI = "http://ftp.gnome.org/pub/GNOME/sources/${BPN}/${SHRT_VER}/${BP}.tar.xz"
|
|
SRC_URI[sha256sum] = "f2affe7d40ab63db8e7b9ecc3f6bdc9c2fc7e3134c84ff2d795f482fe926a382"
|
|
|
|
inherit autotools pkgconfig upstream-version-is-even
|
|
|
|
FILES:${PN} += "${datadir}/${BPN}-${SHRT_VER}/vapi ${libdir}/${BPN}-${SHRT_VER}/"
|
|
FILES:${PN}-doc += "${datadir}/devhelp"
|
|
|
|
# .gir files from gobject-introspection are installed to ${libdir} when multilib is enabled
|
|
GIRDIR_OPT = "${@'--girdir=${STAGING_LIBDIR}/gir-1.0' if d.getVar('MULTILIBS') else ''}"
|
|
|
|
do_configure:prepend:class-target() {
|
|
# Write out a vapigen wrapper that will be provided by pkg-config file installed in target sysroot
|
|
# The wrapper will call a native vapigen
|
|
cat > ${B}/vapigen-wrapper << EOF
|
|
#!/bin/sh
|
|
vapigen-${SHRT_VER} ${GIRDIR_OPT} "\$@"
|
|
EOF
|
|
chmod +x ${B}/vapigen-wrapper
|
|
}
|
|
|
|
EXTRA_OECONF += " --disable-valadoc"
|
|
|
|
# Vapigen wrapper needs to be available system-wide, because it will be used
|
|
# to build vapi files from all other packages with vala support
|
|
do_install:append:class-target() {
|
|
install -d ${D}${bindir_crossscripts}/
|
|
install ${B}/vapigen-wrapper ${D}${bindir_crossscripts}/
|
|
}
|
|
|
|
# Put vapigen wrapper into target sysroot so that it can be used when building
|
|
# vapi files.
|
|
SYSROOT_DIRS += "${bindir_crossscripts}"
|
|
|
|
inherit multilib_script
|
|
MULTILIB_SCRIPTS = "${PN}:${bindir}/vala-gen-introspect-0.56"
|
|
|
|
SYSROOT_PREPROCESS_FUNCS:append:class-target = " vapigen_sysroot_preprocess"
|
|
vapigen_sysroot_preprocess() {
|
|
# Tweak the vapigen name in the vapigen pkgconfig file, so that it picks
|
|
# up our wrapper.
|
|
sed -i \
|
|
-e "s|vapigen=.*|vapigen=${bindir_crossscripts}/vapigen-wrapper|" \
|
|
${SYSROOT_DESTDIR}${libdir}/pkgconfig/vapigen-${SHRT_VER}.pc
|
|
}
|
|
|
|
SSTATE_SCAN_FILES += "vapigen-wrapper"
|
|
|
|
PACKAGE_PREPROCESS_FUNCS += "vala_package_preprocess"
|
|
|
|
vala_package_preprocess () {
|
|
rm -rf ${PKGD}${bindir_crossscripts}
|
|
}
|