mirror of
https://git.yoctoproject.org/poky
synced 2026-02-08 18:02:12 +01:00
7e55fd135f
Changelog: - Update the syscall table for Linux v6.13 - Add support for new arches: SuperH little and big endian, LoongArch, and 32-bit Motorola 68000 - Add multiplexed syscall support for more arches: MIPS, SuperH, and PPC - Consolidate and simplify handling of multiplexed syscalls - Add support for the SECCOMP_FILTER_FLAG_WAIT_KILLABLE_RECV flag - Add support for transactions with the seccomp_transaction_start(), seccomp_transaction_commit(), and seccomp_transaction_reject() APIs - Add a seccomp_precompute() API to generate the seccomp BPF filter prior to seccomp_load() or seccomp_export_bpf_mem() - Add support for binary tree filters without syscalls - Add support for the kernel’s implementation change of SECCOMP_IOCTL_NOTIF_ID_VALID - Add Python binding support for retrieving the notification file descriptor - Improved tooling to help track syscall table updates in the Linux kernel - Handle EINVAL error from the kernel when the WAIT_KILLABLE_RECV flag is erroneously provided to the kernel - Fix a seccomp userspace notification issue where the file descriptor was being requested more than once - Fix a bug where the internal filter state could be corrupted when a filter rule addition fails - Fix potential memory leak in the internal management of filter snapshots - Utilize Cython rather than distutils in the Python bindings, due to distutils’ deprecation - Many test and CI improvements and fixes - Many documentation improvements and updates (From OE-Core rev: 549a477660bd6ccda842b4ed34814b53470d08d8) Signed-off-by: Simone Weiß <simone.p.weiss@posteo.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
63 lines
2.3 KiB
BlitzBasic
63 lines
2.3 KiB
BlitzBasic
SUMMARY = "interface to seccomp filtering mechanism"
|
|
DESCRIPTION = "The libseccomp library provides an easy to use, platform independent, interface to the Linux Kernel's syscall filtering mechanism: seccomp."
|
|
HOMEPAGE = "https://github.com/seccomp/libseccomp"
|
|
SECTION = "security"
|
|
LICENSE = "LGPL-2.1-only"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=7c13b3376cea0ce68d2d2da0a1b3a72c"
|
|
|
|
DEPENDS += "gperf-native"
|
|
|
|
SRCREV = "c7c0caed1d04292500ed4b9bb386566053eb9775"
|
|
|
|
SRC_URI = "git://github.com/seccomp/libseccomp.git;branch=release-2.6;protocol=https \
|
|
file://run-ptest \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit autotools-brokensep pkgconfig ptest features_check
|
|
|
|
inherit_defer ${@bb.utils.contains('PACKAGECONFIG', 'python', 'python3native', '', d)}
|
|
|
|
REQUIRED_DISTRO_FEATURES = "seccomp"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[python] = "--enable-python, --disable-python, python3-cython-native"
|
|
|
|
DISABLE_STATIC = ""
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C tests check-build
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
install -d ${D}${PTEST_PATH}/tools
|
|
for file in $(find tests/* -executable -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
|
|
done
|
|
for file in $(find tests/*.tests -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tests
|
|
done
|
|
for file in $(find tests/*.pfc -type f); do
|
|
install -m 644 ${S}/${file} ${D}/${PTEST_PATH}/tests
|
|
done
|
|
install -m 644 ${S}/tests/valgrind_test.supp ${D}/${PTEST_PATH}/tests
|
|
for file in $(find tools/* -executable -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
|
|
done
|
|
# Overwrite libtool wrappers with real executables
|
|
for file in $(find tools/.libs/* -executable -type f); do
|
|
install -m 744 ${S}/${file} ${D}/${PTEST_PATH}/tools
|
|
done
|
|
# fix python shebang
|
|
sed -i -e 's@cmd /usr/bin/env python @cmd /usr/bin/env python3 @' ${D}/${PTEST_PATH}/tests/regression
|
|
sed -i -e 's@^#!/usr/bin/env python$@#!/usr/bin/env python3@' ${D}/${PTEST_PATH}/tests/*.py
|
|
}
|
|
|
|
FILES:${PN} = "${bindir} ${libdir}/${BPN}.so* ${PYTHON_SITEPACKAGES_DIR}/"
|
|
FILES:${PN}-dbg += "${libdir}/${PN}/tests/.debug/* ${libdir}/${PN}/tools/.debug"
|
|
|
|
RDEPENDS:${PN} += "${@bb.utils.contains('PACKAGECONFIG', 'python', 'python3', '', d)}"
|
|
RDEPENDS:${PN}-ptest = "coreutils bash"
|