mirror of
https://git.yoctoproject.org/poky
synced 2026-02-13 20:23:04 +01:00
32b3f35bf6
fix the issue that: | Error: Transaction test error: | file /usr/libexec/libunwind/check-namespace.sh conflicts between attempted installs of libunwind-1.8.1-r0.core2_64 and lib32-libunwind-1.8.1-r0.core2_32 | file /usr/libexec/libunwind/test-runner conflicts between attempted installs of libunwind-1.8.1-r0.core2_64 and lib32-libunwind-1.8.1-r0.core2_32 By default, test suite from srcdir/tests/* will be installed to /usr/libexec/libunwind, here pass --disable-tests to not install test suite. Test suite can be added to libunwind-ptest in the future if needed (From OE-Core rev: 9d9c36cd5fc59e88bcd8a08ba70ced996c7d74be) Signed-off-by: Liu Yiding <liuyd.fnst@fujitsu.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
2.3 KiB
BlitzBasic
56 lines
2.3 KiB
BlitzBasic
SUMMARY = "Library for obtaining the call-chain of a program"
|
|
DESCRIPTION = "a portable and efficient C programming interface (API) to determine the call-chain of a program"
|
|
HOMEPAGE = "http://www.nongnu.org/libunwind"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=2d80c8ed4062b8339b715f90fa68cc9f"
|
|
DEPENDS:append:libc-musl = " libucontext"
|
|
|
|
GITHUB_BASE_URI = "https://github.com/libunwind/libunwind/releases"
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/v${PV}/${BP}.tar.gz \
|
|
file://mips-byte-order.patch \
|
|
file://0001-tests-Garm64-test-sve-signal-check-that-SVE-is-prese.patch \
|
|
file://0002-coredump-use-glibc-or-musl-register-names-as-appropr.patch \
|
|
file://0003-Fixed-miscompilation-of-unw_getcontext-on-ARM.patch \
|
|
file://0004-Rework-inline-aarch64-as-for-setcontext.patch \
|
|
file://0005-Handle-musl-on-PPC32.patch \
|
|
file://libatomic.patch \
|
|
file://malloc.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "ddf0e32dd5fafe5283198d37e4bf9decf7ba1770b6e7e006c33e6df79e6a6157"
|
|
|
|
inherit autotools multilib_header github-releases
|
|
|
|
COMPATIBLE_HOST:riscv32 = "null"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[lzma] = "--enable-minidebuginfo,--disable-minidebuginfo,xz"
|
|
PACKAGECONFIG[zlib] = "--enable-zlibdebuginfo,--disable-zlibdebuginfo,zlib"
|
|
PACKAGECONFIG[latexdocs] = "--enable-documentation, --disable-documentation, latex2man-native"
|
|
|
|
EXTRA_OECONF = "--enable-static --disable-tests"
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/20487/
|
|
ARM_INSTRUCTION_SET:armv4 = "arm"
|
|
ARM_INSTRUCTION_SET:armv5 = "arm"
|
|
|
|
# With qemuarm64 and poky-tiny:
|
|
# ld: .libs/Gtest-trace: hidden symbol `__aarch64_cas8_acq_rel' in libgcc.a(cas_8_4.o) is referenced by DSO
|
|
LDFLAGS_SECTION_REMOVAL = ""
|
|
|
|
LDFLAGS += "-Wl,-z,relro,-z,now"
|
|
|
|
SECURITY_LDFLAGS:append:libc-musl = " -lssp_nonshared"
|
|
CACHED_CONFIGUREVARS:append:libc-musl = " LDFLAGS='${LDFLAGS} -lucontext'"
|
|
|
|
do_install:append () {
|
|
oe_multilib_header libunwind.h
|
|
}
|
|
|
|
BBCLASSEXTEND = "native"
|
|
|
|
# libunwind-1.8.1/src/elfxx.c:205:44: error: passing argument 3 of '_Uppc32_get_func_addr' from incompatible pointer type [-Wincompatible-pointer-types]
|
|
# libunwind-1.8.1/src/elfxx.c:279:52: error: passing argument 3 of '_Uppc32_get_func_addr' from incompatible pointer type [-Wincompatible-pointer-types]
|
|
# and others
|
|
CFLAGS:append:powerpc:libc-musl = " -Wno-error=incompatible-pointer-types"
|