mirror of
https://git.yoctoproject.org/poky
synced 2026-02-06 16:56:37 +01:00
bb1c719250
* The vm image(hdddirect, vmdk, qcow2, vdi) and live image (hddimg, iso) couldn't be built together because the following vars settings are conflicted: - SYSLINUX_ROOT (/dev/sda2 vs /dev/ram0) - LABELS (boot vs boot install) - INITRD (None vs live install) - SYSLINUX_CFG (see above) Introduce new vars (SYSLINUX_ROOT_VM/_LIVE, the samilar to others) to make them can work together, now we can build all of them together: IMAGE_FSTYPES += "live iso hddimg hdddirect vmdk qcow2 vdi" * Use SYSLINUX_CFG rather than SYSLINUXCFG to keep align with others SYSLINUX vars. * The SYSLINUX_TIMEOUT had been set, but it didn't work since AUTO_SYSLINUXMENU wasn't set, this would cause confusions, so also set AUTO_SYSLINUXMENU. * Move SYSLINUX_PROMPT and SYSLINUX_TIMEOUT to syslinux.bbclass rather than in separate classes since they are the same. * Set SYSLINUX_TIMEOUT to 50 to have a unique timeout for syslinux. [YOCTO #9161] (From OE-Core rev: e38c94d6bf83ed3ca7f046d9503e81b927487bf2) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.9 KiB
Plaintext
50 lines
1.9 KiB
Plaintext
|
|
SYSLINUX_LABELS_VM ?= "boot"
|
|
LABELS_VM ?= "${SYSLINUX_LABELS_VM}"
|
|
|
|
# Using an initramfs is optional. Enable it by setting INITRD_IMAGE_VM.
|
|
INITRD_IMAGE_VM ?= ""
|
|
INITRD_VM ?= "${@'${DEPLOY_DIR_IMAGE}/${INITRD_IMAGE_VM}-${MACHINE}.cpio.gz' if '${INITRD_IMAGE_VM}' else ''}"
|
|
do_bootdirectdisk[depends] += "${@'${INITRD_IMAGE_VM}:do_image_complete' if '${INITRD_IMAGE_VM}' else ''}"
|
|
|
|
# need to define the dependency and the ROOTFS for directdisk
|
|
do_bootdirectdisk[depends] += "${PN}:do_image_ext4"
|
|
ROOTFS ?= "${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.ext4"
|
|
|
|
# creating VM images relies on having a hdddirect so ensure we inherit it here.
|
|
inherit boot-directdisk
|
|
|
|
IMAGE_TYPEDEP_vmdk = "ext4"
|
|
IMAGE_TYPEDEP_vdi = "ext4"
|
|
IMAGE_TYPEDEP_qcow2 = "ext4"
|
|
IMAGE_TYPEDEP_hdddirect = "ext4"
|
|
IMAGE_TYPES_MASKED += "vmdk vdi qcow2 hdddirect"
|
|
|
|
create_vmdk_image () {
|
|
qemu-img convert -O vmdk ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.hdddirect ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.vmdk
|
|
ln -sf ${IMAGE_NAME}.vmdk ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.vmdk
|
|
}
|
|
|
|
create_vdi_image () {
|
|
qemu-img convert -O vdi ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.hdddirect ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.vdi
|
|
ln -sf ${IMAGE_NAME}.vdi ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.vdi
|
|
}
|
|
|
|
create_qcow2_image () {
|
|
qemu-img convert -O qcow2 ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.hdddirect ${DEPLOY_DIR_IMAGE}/${IMAGE_NAME}.qcow2
|
|
ln -sf ${IMAGE_NAME}.qcow2 ${DEPLOY_DIR_IMAGE}/${IMAGE_LINK_NAME}.qcow2
|
|
}
|
|
|
|
python do_vmimg() {
|
|
if 'vmdk' in d.getVar('IMAGE_FSTYPES', True):
|
|
bb.build.exec_func('create_vmdk_image', d)
|
|
if 'vdi' in d.getVar('IMAGE_FSTYPES', True):
|
|
bb.build.exec_func('create_vdi_image', d)
|
|
if 'qcow2' in d.getVar('IMAGE_FSTYPES', True):
|
|
bb.build.exec_func('create_qcow2_image', d)
|
|
}
|
|
|
|
addtask vmimg after do_bootdirectdisk before do_image_complete
|
|
do_vmimg[depends] += "qemu-native:do_populate_sysroot"
|
|
|