mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
87a19bbc3c
Fixes: [YOCTO #13471] (From OE-Core rev: 54e0df20665be8df9d8961d8c4e716e38104ba16) Signed-off-by: Ida Delphine <idadelm@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 6db24928d62aeb093a0e6da6619713eaca57a96f) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
65 lines
2.3 KiB
PHP
65 lines
2.3 KiB
PHP
SUMMARY = "Utilities for manipulating filesystem extended attributes"
|
|
DESCRIPTION = "Implement the ability for a user to attach name:value pairs to objects within the XFS filesystem."
|
|
|
|
HOMEPAGE = "http://savannah.nongnu.org/projects/attr/"
|
|
SECTION = "libs"
|
|
|
|
DEPENDS = "virtual/libintl"
|
|
|
|
LICENSE = "LGPLv2.1+ & GPLv2+"
|
|
LICENSE_${PN} = "GPLv2+"
|
|
LICENSE_lib${BPN} = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://doc/COPYING;md5=2d0aa14b3fce4694e4f615e30186335f \
|
|
file://tools/attr.c;endline=17;md5=be0403261f0847e5f43ed5b08d19593c \
|
|
file://libattr/libattr.c;endline=17;md5=7970f77049f8fa1199fff62a7ab724fb"
|
|
|
|
SRC_URI = "${SAVANNAH_GNU_MIRROR}/attr/${BP}.tar.gz \
|
|
file://run-ptest \
|
|
"
|
|
|
|
inherit ptest update-alternatives autotools gettext
|
|
|
|
PACKAGES =+ "lib${BPN}"
|
|
|
|
FILES_lib${BPN} = "${libdir}/lib*${SOLIBS}"
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
ALTERNATIVE_${PN} = "setfattr"
|
|
ALTERNATIVE_TARGET[setfattr] = "${bindir}/setfattr"
|
|
|
|
PTEST_BUILD_HOST_FILES = "builddefs"
|
|
PTEST_BUILD_HOST_PATTERN = "^RPM"
|
|
|
|
do_install_ptest() {
|
|
cp ${B}/Makefile ${D}${PTEST_PATH}
|
|
sed -e 's,--sysroot=${STAGING_DIR_TARGET},,g' \
|
|
-e 's|${DEBUG_PREFIX_MAP}||g' \
|
|
-e 's:${HOSTTOOLS_DIR}/::g' \
|
|
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
|
-e 's:${BASE_WORKDIR}/${MULTIMACH_TARGET_SYS}::g' \
|
|
-i ${D}${PTEST_PATH}/Makefile
|
|
|
|
sed -i "s|^srcdir =.*|srcdir = \.|g" ${D}${PTEST_PATH}/Makefile
|
|
sed -i "s|^abs_srcdir =.*|abs_srcdir = \.|g" ${D}${PTEST_PATH}/Makefile
|
|
sed -i "s|^abs_top_srcdir =.*|abs_top_srcdir = \.\.|g" ${D}${PTEST_PATH}/Makefile
|
|
sed -i "s|^Makefile:.*|Makefile:|g" ${D}${PTEST_PATH}/Makefile
|
|
cp -rf ${S}/build-aux/ ${D}${PTEST_PATH}
|
|
cp -rf ${S}/test/ ${D}${PTEST_PATH}
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest = "attr \
|
|
coreutils \
|
|
perl-module-filehandle \
|
|
perl-module-getopt-std \
|
|
perl-module-posix \
|
|
make \
|
|
perl \
|
|
gawk \
|
|
perl-module-cwd \
|
|
perl-module-file-basename \
|
|
perl-module-file-path \
|
|
perl-module-file-spec \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|