mirror of
https://git.yoctoproject.org/poky
synced 2026-02-07 01:06:37 +01:00
b7b382101b
Nothing is being built so there is no need for the cross-compiler. (From OE-Core rev: d1d09bd4d7be88f0e341d5fccbfbefeb98d4b727) Signed-off-by: Peter Kjellerstedt <peter.kjellerstedt@axis.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.2 KiB
Plaintext
46 lines
1.2 KiB
Plaintext
#
|
|
# Copyright OpenEmbedded Contributors
|
|
#
|
|
# SPDX-License-Identifier: MIT
|
|
#
|
|
|
|
# Common variable and task for the binary package recipe.
|
|
# Basic principle:
|
|
# * The files have been unpacked to ${S} by base.bbclass
|
|
# * Skip do_configure and do_compile
|
|
# * Use do_install to install the files to ${D}
|
|
#
|
|
# Note:
|
|
# The "subdir" parameter in the SRC_URI is useful when the input package
|
|
# is rpm, ipk, deb and so on, for example:
|
|
#
|
|
# SRC_URI = "http://foo.com/foo-1.0-r1.i586.rpm;subdir=foo-1.0"
|
|
#
|
|
# Then the files would be unpacked to ${WORKDIR}/foo-1.0, otherwise
|
|
# they would be in ${WORKDIR}.
|
|
#
|
|
|
|
# Nothing is being built so there is no need for the cross-compiler.
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
# Skip the unwanted steps
|
|
do_configure[noexec] = "1"
|
|
do_compile[noexec] = "1"
|
|
|
|
# Install the files to ${D}
|
|
bin_package_do_install () {
|
|
# Do it carefully
|
|
[ -d "${S}" ] || exit 1
|
|
if [ -z "$(ls -A ${S})" ]; then
|
|
bbfatal bin_package has nothing to install. Be sure the SRC_URI unpacks into S.
|
|
fi
|
|
cd ${S}
|
|
install -d ${D}${base_prefix}
|
|
tar --no-same-owner --exclude='./patches' --exclude='./.pc' -cpf - . \
|
|
| tar --no-same-owner -xpf - -C ${D}${base_prefix}
|
|
}
|
|
|
|
FILES:${PN} = "/"
|
|
|
|
EXPORT_FUNCTIONS do_install
|