mirror of
https://git.yoctoproject.org/poky
synced 2026-05-31 03:52:39 +02:00
de5e1bc5dd
Changelog: ============ - Remove K&R function definitions and zlib2ansi - Fix bug in deflateBound() for level 0 and memLevel 9 - Fix bug when gzungetc() is used immediately after gzopen() - Fix bug when using gzflush() with a very small buffer - Fix crash when gzsetparams() attempted for transparent write - Fix test/example.c to work with FORCE_STORED - Rewrite of zran in examples (see zran.c version history) - Fix minizip to allow it to open an empty zip file - Fix reading disk number start on zip64 files in minizip - Fix logic error in minizip argument processing - Add minizip testing to Makefile - Read multiple bytes instead of byte-by-byte in minizip unzip.c - Add memory sanitizer to configure (--memory) - Various portability improvements - Various documentation improvements - Various spelling and typo corrections (From OE-Core rev: 369780c635cb99a3d93c38dc4e3944eba5a2c2cd) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
48 lines
1.3 KiB
BlitzBasic
48 lines
1.3 KiB
BlitzBasic
SUMMARY = "Zlib Compression Library"
|
|
DESCRIPTION = "Zlib is a general-purpose, patent-free, lossless data compression \
|
|
library which is used by many different programs."
|
|
HOMEPAGE = "http://zlib.net/"
|
|
SECTION = "libs"
|
|
LICENSE = "Zlib"
|
|
LIC_FILES_CHKSUM = "file://zlib.h;beginline=6;endline=23;md5=5377232268e952e9ef63bc555f7aa6c0"
|
|
|
|
# The source tarball needs to be .gz as only the .gz ends up in fossils/
|
|
SRC_URI = "https://zlib.net/${BP}.tar.gz \
|
|
file://0001-configure-Pass-LDFLAGS-to-link-tests.patch \
|
|
file://run-ptest \
|
|
"
|
|
UPSTREAM_CHECK_URI = "http://zlib.net/"
|
|
|
|
SRC_URI[sha256sum] = "ff0ba4c292013dbc27530b3a81e1f9a813cd39de01ca5e0f8bf355702efa593e"
|
|
|
|
# When a new release is made the previous release is moved to fossils/, so add this
|
|
# to PREMIRRORS so it is also searched automatically.
|
|
PREMIRRORS:append = " https://zlib.net/ https://zlib.net/fossils/"
|
|
|
|
CFLAGS += "-D_REENTRANT"
|
|
|
|
RDEPENDS:${PN}-ptest += "make"
|
|
|
|
inherit ptest
|
|
|
|
B = "${WORKDIR}/build"
|
|
|
|
do_configure() {
|
|
LDCONFIG=true ${S}/configure --prefix=${prefix} --shared --libdir=${libdir} --uname=GNU
|
|
}
|
|
do_configure[cleandirs] += "${B}"
|
|
|
|
do_compile() {
|
|
oe_runmake shared
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install ${B}/examplesh ${D}${PTEST_PATH}
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|