mirror of
https://git.yoctoproject.org/poky
synced 2026-02-14 20:53:03 +01:00
0ef2e5081b
strip can be coming from binutils or from llvm in some cases llvm-strip can fail on kernel Subprocess output:aarch64-yoe-linux-llvm-strip: error: Link field value 28 in section .rela.dyn is not a symbol table This helps in selecting which strip is used when building kernel (From OE-Core rev: 03973c8c1c93ddb1c8e05b773bfcc45aed73a99f) Signed-off-by: Khem Raj <raj.khem@gmail.com> Cc: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
43 lines
1.3 KiB
BlitzBasic
43 lines
1.3 KiB
BlitzBasic
SUMMARY = "UProbes kernel module for SystemTap"
|
|
HOMEPAGE = "https://sourceware.org/systemtap/"
|
|
require systemtap_git.inc
|
|
|
|
DEPENDS = "systemtap virtual/kernel"
|
|
|
|
# On systems without CONFIG_UTRACE, this package is empty.
|
|
ALLOW_EMPTY:${PN} = "1"
|
|
|
|
inherit module-base gettext
|
|
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/systemtap:"
|
|
|
|
FILES:${PN} += "${datadir}/systemtap/runtime/uprobes"
|
|
|
|
# Compile and install the uprobes kernel module on machines with utrace
|
|
# support. Note that staprun expects it in the systemtap/runtime directory,
|
|
# not in /lib/modules.
|
|
do_compile() {
|
|
if grep -q "CONFIG_UTRACE=y" ${STAGING_KERNEL_BUILDDIR}/.config
|
|
then
|
|
unset CFLAGS CPPFLAGS CXXFLAGS LDFLAGS CC LD CPP
|
|
oe_runmake CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
|
|
AR="${KERNEL_AR}" OBJCOPY="${KERNEL_OBJCOPY}" \
|
|
STRIP="${KERNEL_STRIP}" \
|
|
-C ${STAGING_KERNEL_DIR} scripts
|
|
oe_runmake KDIR=${STAGING_KERNEL_DIR} \
|
|
M="${S}/runtime/uprobes/" \
|
|
CC="${KERNEL_CC}" LD="${KERNEL_LD}" \
|
|
AR="${KERNEL_AR}" OBJCOPY="${KERNEL_OBJCOPY}" \
|
|
STRIP="${KERNEL_STRIP}" \
|
|
-C "${S}/runtime/uprobes/"
|
|
fi
|
|
}
|
|
|
|
do_install() {
|
|
if [ -e "${S}/runtime/uprobes/uprobes.ko" ]
|
|
then
|
|
install -d ${D}${datadir}/systemtap/runtime/uprobes/
|
|
install -m 0644 ${S}/runtime/uprobes/uprobes.ko ${D}${datadir}/systemtap/runtime/uprobes/
|
|
fi
|
|
}
|