mirror of
https://git.yoctoproject.org/poky
synced 2026-03-01 21:09:39 +01:00
315e8835ec
Integrating the 4.9-rt4 new changes: 56a3dd6fb4e9 x86/mm/cpa: avoid wbinvd() for PREEMPT 221db3244e71 pinctrl: qcom: Use raw spinlock variants 43158f23e188 radix-tree: use local locks 109a8fea2c4a cpuset: Convert callback_lock to raw_spinlock_t 3741fb19d20f softirq: wake the timer softirq if needed (From OE-Core rev: c1fd9a544d2165c0f3d827d3ad3c90f9c7781f09) Signed-off-by: Bruce Ashfield <bruce.ashfield@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
39 lines
1.4 KiB
BlitzBasic
39 lines
1.4 KiB
BlitzBasic
KBRANCH ?= "standard/preempt-rt/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# Skip processing of this recipe if it is not explicitly specified as the
|
|
# PREFERRED_PROVIDER for virtual/kernel. This avoids errors when trying
|
|
# to build multiple virtual/kernel providers, e.g. as dependency of
|
|
# core-image-rt-sdk, core-image-rt.
|
|
python () {
|
|
if d.getVar("PREFERRED_PROVIDER_virtual/kernel") != "linux-yocto-rt":
|
|
raise bb.parse.SkipPackage("Set PREFERRED_PROVIDER_virtual/kernel to linux-yocto-rt to enable it")
|
|
}
|
|
|
|
SRCREV_machine ?= "01a64b0469256a432af0b8a0f27d32694e908e8b"
|
|
SRCREV_meta ?= "8d1042fc4b23d184688b0e6931dd4e7ff4807273"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto-4.9.git;branch=${KBRANCH};name=machine \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-4.9;destsuffix=${KMETA}"
|
|
|
|
LINUX_VERSION ?= "4.9.8"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "2"
|
|
|
|
LINUX_KERNEL_TYPE = "preempt-rt"
|
|
|
|
COMPATIBLE_MACHINE = "(qemux86|qemux86-64|qemuarm|qemuppc|qemumips)"
|
|
|
|
KERNEL_DEVICETREE_qemuarm = "versatile-pb.dtb"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES_append_qemuall=" cfg/virtio.scc"
|
|
KERNEL_FEATURES_append_qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES_append_qemux86-64=" cfg/sound.scc"
|