mirror of
https://git.yoctoproject.org/poky
synced 2026-09-24 22:36:21 +02:00
321844ee11
The homepage: https://www.kernel.org/doc/man-pages/download.html specifies that the latest tarballs are published one level up from where we currently take them. (From OE-Core rev: 3722fc6f7804107bc95619576d9789259acd7f68) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
38 lines
1.1 KiB
BlitzBasic
38 lines
1.1 KiB
BlitzBasic
SUMMARY = "Linux man-pages"
|
|
DESCRIPTION = "The Linux man-pages project documents the Linux kernel and C library interfaces that are employed by user programs"
|
|
SECTION = "console/utils"
|
|
HOMEPAGE = "http://www.kernel.org/pub/linux/docs/man-pages"
|
|
LICENSE = "GPLv2+"
|
|
|
|
LIC_FILES_CHKSUM = "file://README;md5=794f701617cc03fe50c53257660d8ec4"
|
|
SRC_URI = "${KERNELORG_MIRROR}/linux/docs/${BPN}/${BP}.tar.gz"
|
|
|
|
SRC_URI[md5sum] = "38abead776a506109e128ab96bcbbe58"
|
|
SRC_URI[sha256sum] = "070bef794c6826b3fb3965d1a2efdb46c25cb37c06c715987f88a50906cd5b6f"
|
|
|
|
inherit manpages
|
|
|
|
MAN_PKG = "${PN}"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[manpages] = ""
|
|
|
|
do_configure[noexec] = "1"
|
|
do_compile[noexec] = "1"
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
# Only deliveres man-pages so FILES_${PN} gets everything
|
|
FILES_${PN}-doc = ""
|
|
FILES_${PN} = "${mandir}/*"
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
ALTERNATIVE_${PN} = "passwd.5 getspnam.3 crypt.3"
|
|
ALTERNATIVE_LINK_NAME[passwd.5] = "${mandir}/man5/passwd.5"
|
|
ALTERNATIVE_LINK_NAME[getspnam.3] = "${mandir}/man3/getspnam.3"
|
|
ALTERNATIVE_LINK_NAME[crypt.3] = "${mandir}/man3/crypt.3"
|