mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 18:32:20 +02:00
4d7b2d2944
This is the final upgrade of udev. Futher upgrades will only come in conjunction with systemd. The v4l1 removal patch is deprecated as the bug is fixed inside udev. There is a new patch fixing the path for default sh interpreter. New debug binaries are generated, and udev.inc is modified to package those correctly. The install locations changed for udevd and udevadm, so the scripts are updated accordingly. (From OE-Core rev: 3cbe52b94c4d559a037347ac419fafee5af84fe6) (From OE-Core rev: 8fc73baecf1b21b1a3e7eff478e25d2a7cae2879) Signed-off-by: Alexandru DAMIAN <alexandru.damian@intel.com> Conflicts: meta/recipes-core/udev/udev_164.bb sgw - Fixed up DEPENDS += and added some OECONF options that where in the meta-oe version and make sense to be included. Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
101 lines
4.2 KiB
PHP
101 lines
4.2 KiB
PHP
SUMMARY = "/dev/ and hotplug management daemon"
|
|
DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
|
|
/dev/, handles hotplug events and loads drivers at boot time."
|
|
HOMEPAGE = "http://www.kernel.org/pub/linux/utils/kernel/hotplug/udev/udev.html"
|
|
LICENSE = "GPLv2.0+ & LGPLv2.1+"
|
|
LICENSE_${PN} = "GPLv2.0+"
|
|
LICENSE_libudev = "LGPLv2.1+"
|
|
LICENSE_libgudev = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://src/COPYING;md5=17c4e5fb495e6707ac92a3864926f979 \
|
|
file://src/gudev/COPYING;md5=fb494485a7d0505308cb68e4997cc266"
|
|
|
|
|
|
DEPENDS = "acl glib-2.0 libusb usbutils pciutils gperf-native libxslt-native util-linux"
|
|
RPROVIDES_${PN} = "hotplug"
|
|
RRECOMMENDS_${PN} += "udev-extraconf usbutils-ids pciutils-ids"
|
|
RDEPENDS_libudev = "${PN} (= ${EXTENDPKGV})"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/linux/utils/kernel/hotplug/udev-${PV}.tar.gz \
|
|
file://0001-Fixing-keyboard_force_release.sh-shell-script-path.patch \
|
|
file://run.rules \
|
|
file://udev.rules \
|
|
file://devfs-udev.rules \
|
|
file://links.conf \
|
|
file://permissions.rules \
|
|
file://local.rules \
|
|
file://udev-cache \
|
|
file://udev-cache.default \
|
|
file://init"
|
|
|
|
inherit autotools pkgconfig update-rc.d
|
|
|
|
# udevd/udevadm -> /sbin/, libudev.so.* -> /lib/
|
|
sbindir = "${base_sbindir}"
|
|
libexecdir = "${base_libdir}"
|
|
EXTRA_OECONF = "--disable-introspection \
|
|
--with-rootlibdir=${base_libdir} \
|
|
--with-pci-ids-path=${datadir}/pci.ids \
|
|
ac_cv_file__usr_share_pci_ids=no \
|
|
ac_cv_file__usr_share_hwdata_pci_ids=no \
|
|
ac_cv_file__usr_share_misc_pci_ids=yes \
|
|
--sbindir=${base_sbindir} \
|
|
--libexecdir=${base_libdir} \
|
|
--with-rootlibdir=${base_libdir} \
|
|
--with-rootprefix= \
|
|
"
|
|
|
|
PACKAGES =+ "udev-acl udev-consolekit udev-utils"
|
|
PACKAGES =+ "udev-cache libudev libudev-dev libudev-dbg"
|
|
PACKAGES =+ "libgudev libgudev-dev libgudev-dbg"
|
|
|
|
INITSCRIPT_PACKAGES = "udev udev-cache"
|
|
INITSCRIPT_NAME_udev = "udev"
|
|
INITSCRIPT_PARAMS_udev = "start 03 S ."
|
|
INITSCRIPT_NAME_udev-cache = "udev-cache"
|
|
INITSCRIPT_PARAMS_udev-cache = "start 36 S ."
|
|
|
|
FILES_${PN} += "${libexecdir} ${libdir}/ConsoleKit"
|
|
RRECOMMENDS_${PN} += "udev-utils"
|
|
|
|
FILES_${PN}-dbg += "${libexecdir}/.debug"
|
|
FILES_${PN}-dbg += "${base_libdir}/udev/.debug/"
|
|
FILES_${PN}-dbg += "${base_libdir}/udev/.debug/*"
|
|
FILES_${PN}-dev = "${datadir}/pkgconfig/udev.pc"
|
|
FILES_libudev = "${base_libdir}/libudev.so.*"
|
|
FILES_libudev-dbg = "${base_libdir}/.debug/libudev.so.*"
|
|
FILES_libudev-dev = "${includedir}/libudev.h ${libdir}/libudev.so ${libdir}/libudev.la \
|
|
${libdir}/libudev.a ${libdir}/pkgconfig/libudev.pc"
|
|
FILES_libgudev = "${base_libdir}/libgudev*.so.* ${libdir}/libgudev*.so.*"
|
|
FILES_libgudev-dbg = "${base_libdir}/.debug/libgudev*.so.* ${libdir}/.debug/libgudev*.so.*"
|
|
FILES_libgudev-dev = "${includedir}/gudev* ${libdir}/libgudev*.so ${libdir}/libgudev*.la \
|
|
${libdir}/libgudev*.a ${libdir}/pkgconfig/gudev*.pc"
|
|
FILES_udev-cache = "${sysconfdir}/init.d/udev-cache ${sysconfdir}/default/udev-cache"
|
|
|
|
FILES_udev-acl = "${base_libdir}/udev/udev-acl ${base_libdir}/udev/rules.d/70-acl.rules"
|
|
|
|
FILES_udev-utils = "${bindir}/udevinfo ${bindir}/udevtest ${base_sbindir}/udevadm"
|
|
|
|
RDEPENDS_udev-consolekit += "udev-acl"
|
|
FILES_udev-consolekit = "${libdir}/ConsoleKit"
|
|
|
|
do_install_append () {
|
|
install -d ${D}${sysconfdir}/init.d
|
|
install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
|
|
install -m 0755 ${WORKDIR}/udev-cache ${D}${sysconfdir}/init.d/udev-cache
|
|
|
|
install -d ${D}${sysconfdir}/default
|
|
install -m 0755 ${WORKDIR}/udev-cache.default ${D}${sysconfdir}/default/udev-cache
|
|
|
|
touch ${D}${sysconfdir}/udev/cache.data
|
|
|
|
install -d ${D}${sysconfdir}/udev/rules.d/
|
|
|
|
install -m 0644 ${WORKDIR}/local.rules ${D}${sysconfdir}/udev/rules.d/local.rules
|
|
|
|
# hid2hci has moved to bluez4. removed in udev as of version 169
|
|
rm -f ${D}${base_libdir}/udev/hid2hci
|
|
|
|
echo 'run_path="/var/run/udev"' >> ${D}${sysconfdir}/udev/udev.conf
|
|
}
|