mirror of
https://git.yoctoproject.org/poky
synced 2026-04-29 18:32:20 +02:00
cec8b230cf
A lot of our recipes had short one-line DESCRIPTION values and no SUMMARY value set. In this case it's much better to just set SUMMARY since DESCRIPTION is defaulted from SUMMARY anyway and then the SUMMARY is at least useful. I also took the opportunity to fix up a lot of the new SUMMARY values, making them concisely explain the function of the recipe / package where possible. (From OE-Core rev: b8feee3cf21f70ba4ec3b822d2f596d4fc02a292) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
83 lines
1.8 KiB
BlitzBasic
83 lines
1.8 KiB
BlitzBasic
SUMMARY = "Inittab configuration for SysVinit"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/GPL-2.0;md5=801f80980d171dd6425610833a22dbe6"
|
|
|
|
PR = "r9"
|
|
|
|
SRC_URI = "file://inittab"
|
|
|
|
S = "${WORKDIR}/sysvinit-${PV}"
|
|
|
|
INHIBIT_DEFAULT_DEPS = "1"
|
|
|
|
do_compile() {
|
|
:
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sysconfdir}
|
|
install -m 0644 ${WORKDIR}/inittab ${D}${sysconfdir}/inittab
|
|
|
|
tmp="${SERIAL_CONSOLES}"
|
|
for i in $tmp
|
|
do
|
|
j=`echo ${i} | sed s/\;/\ /g`
|
|
label=`echo ${i} | sed -e 's/^.*;tty//' -e 's/;.*//'`
|
|
echo "$label:12345:respawn:${base_sbindir}/getty ${j}" >> ${D}${sysconfdir}/inittab
|
|
done
|
|
|
|
if [ "${USE_VT}" = "1" ]; then
|
|
cat <<EOF >>${D}${sysconfdir}/inittab
|
|
# ${base_sbindir}/getty invocations for the runlevels.
|
|
#
|
|
# The "id" field MUST be the same as the last
|
|
# characters of the device (after "tty").
|
|
#
|
|
# Format:
|
|
# <id>:<runlevels>:<action>:<process>
|
|
#
|
|
|
|
EOF
|
|
|
|
for n in ${SYSVINIT_ENABLED_GETTYS}
|
|
do
|
|
echo "$n:2345:respawn:${base_sbindir}/getty 38400 tty$n" >> ${D}${sysconfdir}/inittab
|
|
done
|
|
echo "" >> ${D}${sysconfdir}/inittab
|
|
fi
|
|
}
|
|
|
|
pkg_postinst_${PN} () {
|
|
# run this on the target
|
|
if [ "x$D" = "x" ] && [ -e /proc/consoles ]; then
|
|
tmp="${SERIAL_CONSOLES_CHECK}"
|
|
for i in $tmp
|
|
do
|
|
j=`echo ${i} | sed s/^.*\;//g`
|
|
if [ -z "`cat /proc/consoles | grep ${j}`" ]; then
|
|
sed -i /^.*${j}$/d /etc/inittab
|
|
fi
|
|
done
|
|
kill -HUP 1
|
|
else
|
|
if [ "${SERIAL_CONSOLES_CHECK}" = "" ]; then
|
|
exit 0
|
|
else
|
|
exit 1
|
|
fi
|
|
fi
|
|
}
|
|
|
|
# USE_VT and SERIAL_CONSOLES are generally defined by the MACHINE .conf.
|
|
# Set PACKAGE_ARCH appropriately.
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
|
|
FILES_${PN} = "${sysconfdir}/inittab"
|
|
CONFFILES_${PN} = "${sysconfdir}/inittab"
|
|
|
|
USE_VT ?= "1"
|
|
SYSVINIT_ENABLED_GETTYS ?= "1"
|
|
|
|
|
|
|