mirror of
https://git.yoctoproject.org/poky
synced 2026-02-20 08:29:42 +01:00
5b711eb91e
The gperf-native is actually needed to generate hash functions, change to depend on the native one. (From OE-Core rev: 3285fdfe7dc13b068e7f3cd727e5c789cd22b26b) Signed-off-by: Jackie Huang <jackie.huang@windriver.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.4 KiB
BlitzBasic
41 lines
1.4 KiB
BlitzBasic
# Copyright (C) 2012 Khem Raj <raj.khem@gmail.com>
|
|
# Released under the MIT license (see COPYING.MIT for the terms)
|
|
|
|
SUMMARY = "Linux kernel style configuration framework for other projects"
|
|
DESCRIPTION = "The kconfig-frontends project aims at centralising \
|
|
the effort of keeping an up-to-date, out-of-tree, packaging of the \
|
|
kconfig infrastructure, ready for use by third-party projects. \
|
|
The kconfig-frontends package provides the kconfig parser, as well as all \
|
|
the frontends"
|
|
HOMEPAGE = "http://ymorin.is-a-geek.org/projects/kconfig-frontends"
|
|
LICENSE = "GPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=9b8cf60ff39767ff04b671fca8302408"
|
|
SECTION = "devel"
|
|
DEPENDS += "ncurses flex bison gperf-native pkgconfig-native"
|
|
RDEPENDS_${PN} += "python"
|
|
SRC_URI = "http://ymorin.is-a-geek.org/download/${BPN}/${BP}.tar.xz"
|
|
|
|
SRC_URI[md5sum] = "b939280dcc83f8feabd87a1d5f9b00c2"
|
|
SRC_URI[sha256sum] = "ea2615a62c74bea6ce3b38402f00c7513858f307f6ba7aa9fdbf0bbc12bcf407"
|
|
|
|
S = "${WORKDIR}/${BPN}-${PV}"
|
|
|
|
inherit autotools
|
|
do_configure_prepend () {
|
|
mkdir -p scripts/.autostuff/m4
|
|
}
|
|
|
|
do_install_append() {
|
|
ln -s kconfig-conf ${D}${bindir}/conf
|
|
ln -s kconfig-mconf ${D}${bindir}/mconf
|
|
}
|
|
|
|
EXTRA_OECONF += "--disable-gconf --disable-qconf"
|
|
|
|
# Some packages have the version preceeding the .so instead properly
|
|
# versioned .so.<version>, so we need to reorder and repackage.
|
|
SOLIBS = "-${@d.getVar('PV',1)[:-2]}.so"
|
|
FILES_SOLIBSDEV = "${libdir}/libkconfig-parser.so"
|
|
|
|
BBCLASSEXTEND = "native"
|