mirror of
https://git.yoctoproject.org/poky
synced 2026-09-29 07:36:20 +02:00
427882f470
Change is correct but should be in gstreamer recipe not gstreamer-plugins-base This reverts commit f32e90a7f8918aacda61ef6176eb1655742045b4. Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
106 lines
4.7 KiB
BlitzBasic
106 lines
4.7 KiB
BlitzBasic
require gstreamer1.0-plugins-common.inc
|
|
|
|
DESCRIPTION = "'Base' GStreamer plugins and helper libraries"
|
|
HOMEPAGE = "https://gstreamer.freedesktop.org/"
|
|
BUGTRACKER = "https://gitlab.freedesktop.org/gstreamer/gst-plugins-base/-/issues"
|
|
LICENSE = "GPLv2+ & LGPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6762ed442b3822387a51c92d928ead0d \
|
|
file://common/coverage/coverage-report.pl;beginline=2;endline=17;md5=a4e1830fce078028c8f0974161272607"
|
|
|
|
SRC_URI = " \
|
|
https://gstreamer.freedesktop.org/src/gst-plugins-base/gst-plugins-base-${PV}.tar.xz \
|
|
file://get-caps-from-src-pad-when-query-caps.patch \
|
|
file://0001-meson-build-gir-even-when-cross-compiling-if-introsp.patch \
|
|
file://0002-meson-Add-variables-for-gir-files.patch \
|
|
file://0003-ssaparse-enhance-SSA-text-lines-parsing.patch \
|
|
file://0005-viv-fb-Make-sure-config.h-is-included.patch \
|
|
file://0009-glimagesink-Downrank-to-marginal.patch \
|
|
file://CVE-2021-3522.patch \
|
|
"
|
|
SRC_URI[md5sum] = "e3ddb1bae9fb510b49a295f212f1e6e4"
|
|
SRC_URI[sha256sum] = "9f02678b0bbbcc9eff107d3bd89d83ce92fec2154cd607c7c8bd34dc7fee491c"
|
|
|
|
S = "${WORKDIR}/gst-plugins-base-${PV}"
|
|
|
|
DEPENDS += "iso-codes util-linux zlib"
|
|
|
|
inherit gobject-introspection gtk-doc
|
|
|
|
PACKAGES_DYNAMIC =+ "^libgst.*"
|
|
|
|
# opengl packageconfig factored out to make it easy for distros
|
|
# and BSP layers to choose OpenGL APIs/platforms/window systems
|
|
PACKAGECONFIG_GL ?= "${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'gles2 egl', '', d)}"
|
|
|
|
PACKAGECONFIG ??= " \
|
|
${GSTREAMER_ORC} \
|
|
${PACKAGECONFIG_GL} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'alsa x11', d)} \
|
|
jpeg ogg pango png theora vorbis \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland egl', '', d)} \
|
|
"
|
|
|
|
OPENGL_APIS = 'opengl gles2'
|
|
OPENGL_PLATFORMS = 'egl'
|
|
|
|
X11DEPENDS = "virtual/libx11 libsm libxrender libxv"
|
|
X11ENABLEOPTS = "-Dx11=enabled -Dxvideo=enabled -Dxshm=enabled"
|
|
X11DISABLEOPTS = "-Dx11=disabled -Dxvideo=disabled -Dxshm=disabled"
|
|
|
|
PACKAGECONFIG[alsa] = "-Dalsa=enabled,-Dalsa=disabled,alsa-lib"
|
|
PACKAGECONFIG[cdparanoia] = "-Dcdparanoia=enabled,-Dcdparanoia=disabled,cdparanoia"
|
|
PACKAGECONFIG[jpeg] = "-Dgl-jpeg=enabled,-Dgl-jpeg=disabled,jpeg"
|
|
PACKAGECONFIG[ogg] = "-Dogg=enabled,-Dogg=disabled,libogg"
|
|
PACKAGECONFIG[opus] = "-Dopus=enabled,-Dopus=disabled,libopus"
|
|
PACKAGECONFIG[pango] = "-Dpango=enabled,-Dpango=disabled,pango"
|
|
PACKAGECONFIG[png] = "-Dgl-png=enabled,-Dgl-png=disabled,libpng"
|
|
PACKAGECONFIG[theora] = "-Dtheora=enabled,-Dtheora=disabled,libtheora"
|
|
PACKAGECONFIG[tremor] = "-Dtremor=enabled,-Dtremor=disabled,tremor"
|
|
PACKAGECONFIG[visual] = "-Dlibvisual=enabled,-Dlibvisual=disabled,libvisual"
|
|
PACKAGECONFIG[vorbis] = "-Dvorbis=enabled,-Dvorbis=disabled,libvorbis"
|
|
PACKAGECONFIG[x11] = "${X11ENABLEOPTS},${X11DISABLEOPTS},${X11DEPENDS}"
|
|
|
|
# OpenGL API packageconfigs
|
|
PACKAGECONFIG[opengl] = ",,virtual/libgl libglu"
|
|
PACKAGECONFIG[gles2] = ",,virtual/libgles2"
|
|
|
|
# OpenGL platform packageconfigs
|
|
PACKAGECONFIG[egl] = ",,virtual/egl"
|
|
|
|
# OpenGL window systems (except for X11)
|
|
PACKAGECONFIG[gbm] = ",,virtual/libgbm libgudev libdrm"
|
|
PACKAGECONFIG[wayland] = ",,wayland-native wayland wayland-protocols libdrm"
|
|
PACKAGECONFIG[dispmanx] = ",,virtual/libomxil"
|
|
|
|
OPENGL_WINSYS_append = "${@bb.utils.contains('PACKAGECONFIG', 'x11', ' x11', '', d)}"
|
|
OPENGL_WINSYS_append = "${@bb.utils.contains('PACKAGECONFIG', 'gbm', ' gbm', '', d)}"
|
|
OPENGL_WINSYS_append = "${@bb.utils.contains('PACKAGECONFIG', 'wayland', ' wayland', '', d)}"
|
|
OPENGL_WINSYS_append = "${@bb.utils.contains('PACKAGECONFIG', 'dispmanx', ' dispmanx', '', d)}"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dgl-graphene=disabled \
|
|
${@get_opengl_cmdline_list('gl_api', d.getVar('OPENGL_APIS'), d)} \
|
|
${@get_opengl_cmdline_list('gl_platform', d.getVar('OPENGL_PLATFORMS'), d)} \
|
|
${@get_opengl_cmdline_list('gl_winsys', d.getVar('OPENGL_WINSYS'), d)} \
|
|
"
|
|
|
|
GTKDOC_MESON_OPTION = "gtk_doc"
|
|
GTKDOC_MESON_ENABLE_FLAG = "enabled"
|
|
GTKDOC_MESON_DISABLE_FLAG = "disabled"
|
|
|
|
FILES_${PN}-dev += "${libdir}/gstreamer-1.0/include/gst/gl/gstglconfig.h"
|
|
FILES_${MLPREFIX}libgsttag-1.0 += "${datadir}/gst-plugins-base/1.0/license-translations.dict"
|
|
|
|
def get_opengl_cmdline_list(switch_name, options, d):
|
|
selected_options = []
|
|
if bb.utils.contains('DISTRO_FEATURES', 'opengl', True, False, d):
|
|
for option in options.split():
|
|
if bb.utils.contains('PACKAGECONFIG', option, True, False, d):
|
|
selected_options += [option]
|
|
if selected_options:
|
|
return '-D' + switch_name + '=' + ','.join(selected_options)
|
|
else:
|
|
return ''
|
|
|
|
CVE_PRODUCT += "gst-plugins-base"
|