mirror of
https://git.yoctoproject.org/poky
synced 2026-02-26 03:19:41 +01:00
3ab89fa06f
License-Updtate: Copyright years changed
4b4a0e5a6e (diff-7116ef0705885343c9e1b2171a06be0e)
Drop backport patch for mips o32 build fix
Refresh patches to apply on 5.2
(From OE-Core rev: abeb32772b8b3a144e468e5a27b1a31f646317e4)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
58 lines
2.1 KiB
BlitzBasic
58 lines
2.1 KiB
BlitzBasic
SUMMARY = "System call tracing tool"
|
|
HOMEPAGE = "http://strace.io"
|
|
SECTION = "console/utils"
|
|
LICENSE = "LGPL-2.1+ & GPL-2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0169a04810830e94f4b1cfb823c9f592"
|
|
|
|
SRC_URI = "https://strace.io/files/${PV}/strace-${PV}.tar.xz \
|
|
file://disable-git-version-gen.patch \
|
|
file://more-robust-test-for-m32-mx32-compile-support.patch \
|
|
file://update-gawk-paths.patch \
|
|
file://Makefile-ptest.patch \
|
|
file://run-ptest \
|
|
file://0001-Fix-build-when-using-non-glibc-libc-implementation-o.patch \
|
|
file://mips-SIGEMT.patch \
|
|
file://0001-caps-abbrev.awk-fix-gawk-s-path.patch \
|
|
file://0001-tests-sigaction-Check-for-mips-and-alpha-before-usin.patch \
|
|
file://ptest-spacesave.patch \
|
|
"
|
|
SRC_URI[md5sum] = "b9c02b07dcde5125498ce7da69b77baf"
|
|
SRC_URI[sha256sum] = "d513bc085609a9afd64faf2ce71deb95b96faf46cd7bc86048bc655e4e4c24d2"
|
|
|
|
inherit autotools ptest
|
|
|
|
PACKAGECONFIG_class-target ??= "\
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'bluetooth', 'bluez', '', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[bluez] = "ac_cv_header_bluetooth_bluetooth_h=yes,ac_cv_header_bluetooth_bluetooth_h=no,bluez5"
|
|
PACKAGECONFIG[libunwind] = "--with-libunwind,--without-libunwind,libunwind"
|
|
|
|
EXTRA_OECONF += "--enable-mpers=no"
|
|
|
|
CFLAGS_append_libc-musl = " -Dsigcontext_struct=sigcontext"
|
|
|
|
TESTDIR = "tests"
|
|
PTEST_BUILD_HOST_PATTERN = "^(DEB_CHANGELOGTIME|RPM_CHANGELOGTIME|WARN_CFLAGS_FOR_BUILD|LDFLAGS_FOR_BUILD)"
|
|
|
|
do_install_append() {
|
|
# We don't ship strace-graph here because it needs perl
|
|
rm ${D}${bindir}/strace-graph
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${TESTDIR} buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest() {
|
|
oe_runmake -C ${TESTDIR} install-ptest BUILDDIR=${B} DESTDIR=${D}${PTEST_PATH} TESTDIR=${TESTDIR}
|
|
install -m 755 ${S}/test-driver ${D}${PTEST_PATH}
|
|
install -m 644 ${B}/config.h ${D}${PTEST_PATH}
|
|
sed -i -e '/^src/s/strace.*[1-9]/ptest/' ${D}/${PTEST_PATH}/${TESTDIR}/Makefile
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest += "make coreutils grep gawk sed"
|
|
|
|
BBCLASSEXTEND = "native"
|
|
TOOLCHAIN = "gcc"
|