mirror of
https://git.yoctoproject.org/poky
synced 2026-04-27 03:32:12 +02:00
e69f3081e9
Its LIBDIR in Makefile is: LIBDIR = $(PREFIX)/lib This is incorrect for 64 bit bsp, thus will cause build failures on gummiboot: ld: cannot open linker script file /path/to/usr/lib64/elf_x86_64_efi.lds: No such file or directory [YOCTO #6053] (From OE-Core rev: a18e4bef5f284c5b940007e60c7be28128a94c44) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
34 lines
1.1 KiB
BlitzBasic
34 lines
1.1 KiB
BlitzBasic
SUMMARY = "Libraries for producing EFI binaries"
|
|
HOMEPAGE = "http://sourceforge.net/projects/gnu-efi/"
|
|
SECTION = "devel"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://debian/copyright;md5=5fb358a180f484b285b0d99acdc29666"
|
|
|
|
SRC_URI = "http://downloads.sourceforge.net/gnu-efi/gnu-efi_3.0u.orig.tar.gz \
|
|
file://parallel-make.patch \
|
|
file://parallel-make-archives.patch \
|
|
"
|
|
SRC_URI[md5sum] = "d15d3c700e79a1e2938544d73edc572d"
|
|
SRC_URI[sha256sum] = "3c0d450d5829204ca05dcb3b2aae772e52c379b7c7e09146759c6315606f934e"
|
|
|
|
COMPATIBLE_HOST = "(x86_64.*|i.86.*)-linux"
|
|
|
|
S = "${WORKDIR}/gnu-efi-3.0"
|
|
|
|
def gnu_efi_arch(d):
|
|
import re
|
|
tarch = d.getVar("TARGET_ARCH", True)
|
|
if re.match("i[3456789]86", tarch):
|
|
return "ia32"
|
|
return tarch
|
|
|
|
EXTRA_OEMAKE = "'ARCH=${@gnu_efi_arch(d)}' 'CC=${CC}' 'AS=${AS}' 'LD=${LD}' 'AR=${AR}' \
|
|
'RANLIB=${RANLIB}' 'OBJCOPY=${OBJCOPY}' 'PREFIX=${prefix}' 'LIBDIR=${libdir}' \
|
|
"
|
|
|
|
do_install() {
|
|
oe_runmake install INSTALLROOT="${D}"
|
|
}
|
|
|
|
FILES_${PN} += "${libdir}/*.lds"
|