mirror of
https://git.yoctoproject.org/poky
synced 2026-04-25 15:32:13 +02:00
269c8a56d0
buildtest-TESTS and runtest-TESTS targets are required by ptest. In order to have those targets in automake 1.13.4 serial-tests should be specified since parallel-tests is assumed by default and serial-tests is optional. ptest results: PASS: test-cmdline PASS: test-features ================== All 2 tests passed ================== (From OE-Core rev: 15bdef1f25ef567caf2f2e270de899e35da7cca9) Signed-off-by: Tudor Florea <tudor.florea@enea.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
31 lines
1.2 KiB
BlitzBasic
31 lines
1.2 KiB
BlitzBasic
SUMMARY = "Display or change ethernet card settings"
|
|
DESCRIPTION = "A small utility for examining and tuning the settings of your ethernet-based network interfaces."
|
|
HOMEPAGE = "http://www.kernel.org/pub/software/network/ethtool/"
|
|
SECTION = "console/network"
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
|
|
file://ethtool.c;beginline=4;endline=17;md5=c19b30548c582577fc6b443626fc1216"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/software/network/ethtool/ethtool-${PV}.tar.gz \
|
|
file://run-ptest \
|
|
file://avoid_parallel_tests.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "997e20c25c43ad5800f8ae3204455a8a"
|
|
SRC_URI[sha256sum] = "b1a988d6e397bd9d5d73cfd64329f85121936a050174bbfe90f8701fd893a1df"
|
|
|
|
inherit autotools ptest
|
|
RDEPENDS_${PN}-ptest += "make"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest-TESTS
|
|
}
|
|
|
|
do_install_ptest () {
|
|
cp ${B}/Makefile ${D}${PTEST_PATH}
|
|
install ${B}/test-cmdline ${D}${PTEST_PATH}
|
|
install ${B}/test-features ${D}${PTEST_PATH}
|
|
install ${B}/ethtool ${D}${PTEST_PATH}/ethtool
|
|
sed -i 's/^Makefile/_Makefile/' ${D}${PTEST_PATH}/Makefile
|
|
}
|