mirror of
https://git.yoctoproject.org/poky
synced 2026-05-02 18:32:15 +02:00
c44d7b5cde
v2 changes: * update format for commit log * add Upstream-Status for patch ppm2tiff does not check the return value of the TIFFScanlineSize function, which allows remote attackers to cause a denial of service (crash) and possibly execute arbitrary code via a crafted PPM image that triggers an integer overflow, a zero-memory allocation, and a heap-based buffer overflow. http://web.nvd.nist.gov/view/vuln/detail?vulnId=CVE-2012-4564 (From OE-Core rev: 9f02922d44de483ef4d02ce95b55efe79a8b09a2) Signed-off-by: Yue Tao <Yue.Tao@windriver.com> Signed-off-by: Wenzong Fan <wenzong.fan@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
54 lines
2.3 KiB
BlitzBasic
54 lines
2.3 KiB
BlitzBasic
SUMMARY = "Provides support for the Tag Image File Format (TIFF)"
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=34da3db46fab7501992f9615d7e158cf"
|
|
HOMEPAGE = "http://www.remotesensing.org/libtiff/"
|
|
|
|
SRC_URI = "ftp://ftp.remotesensing.org/pub/libtiff/tiff-${PV}.tar.gz \
|
|
file://libtool2.patch \
|
|
file://libtiff-CVE-2013-1960.patch \
|
|
file://libtiff-CVE-2013-4232.patch \
|
|
file://libtiff-CVE-2013-4243.patch \
|
|
file://libtiff-CVE-2013-4244.patch \
|
|
file://libtiff-CVE-2013-4231.patch \
|
|
file://tiff-CVE-2012-4564.patch "
|
|
|
|
SRC_URI[md5sum] = "051c1068e6a0627f461948c365290410"
|
|
SRC_URI[sha256sum] = "ea1aebe282319537fb2d4d7805f478dd4e0e05c33d0928baba76a7c963684872"
|
|
|
|
inherit autotools
|
|
|
|
CACHED_CONFIGUREVARS = "ax_cv_check_gl_libgl=no"
|
|
|
|
PACKAGECONFIG ?= "cxx jpeg zlib lzma \
|
|
strip-chopping extrasample-as-alpha check-ycbcr-subsampling"
|
|
|
|
PACKAGECONFIG[cxx] = "--enable-cxx,--disable-cxx,,"
|
|
PACKAGECONFIG[jpeg] = "--enable-jpeg,--disable-jpeg,jpeg,"
|
|
PACKAGECONFIG[zlib] = "--enable-zlib,--disable-zlib,zlib,"
|
|
PACKAGECONFIG[lzma] = "--enable-lzma,--disable-lzma,xz,"
|
|
|
|
# Convert single-strip uncompressed images to multiple strips of specified
|
|
# size (default: 8192) to reduce memory usage
|
|
PACKAGECONFIG[strip-chopping] = "--enable-strip-chopping,--disable-strip-chopping,,"
|
|
|
|
# Treat a fourth sample with no EXTRASAMPLE_ value as being ASSOCALPHA
|
|
PACKAGECONFIG[extrasample-as-alpha] = "--enable-extrasample-as-alpha,--disable-extrasample-as-alpha,,"
|
|
|
|
# Control picking up YCbCr subsample info. Disable to support files lacking
|
|
# the tag
|
|
PACKAGECONFIG[check-ycbcr-subsampling] = "--enable-check-ycbcr-subsampling,--disable-check-ycbcr-subsampling,,"
|
|
|
|
# Support a mechanism allowing reading large strips (usually one strip files)
|
|
# in chunks when using TIFFReadScanline. Experimental 4.0+ feature
|
|
PACKAGECONFIG[chunky-strip-read] = "--enable-chunky-strip-read,--disable-chunky-strip-read,,"
|
|
|
|
PACKAGES =+ "tiffxx tiffxx-dbg tiffxx-dev tiffxx-staticdev tiff-utils tiff-utils-dbg"
|
|
FILES_tiffxx = "${libdir}/libtiffxx.so.*"
|
|
FILES_tiffxx-dev = "${libdir}/libtiffxx.so ${libdir}/libtiffxx.la"
|
|
FILES_tiffxx-staticdev = "${libdir}/libtiffxx.a"
|
|
FILES_tiffxx-dbg += "${libdir}/.debug/libtiffxx.so*"
|
|
FILES_tiff-utils = "${bindir}/*"
|
|
FILES_tiff-utils-dbg += "${bindir}/.debug/"
|
|
|
|
BBCLASSEXTEND = "native"
|